cogent-2.3.6.ebuild

cogent-2.3.6.ebuild (text/plain), 2.32 KB, created by Ed Catmur on 2006-01-18 15:56:23 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit multilib eutils

DESCRIPTION="A graphical environment for cognitive modelling"
HOMEPAGE="http://cogent.psyc.bbk.ac.uk/"
SRC_URI="http://cogent.psyc.bbk.ac.uk/download/unix/${P}-src.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc gnome kde firefox mozilla"
S="${WORKDIR}"

DEPEND="dev-lang/swi-prolog
	=x11-libs/gtk+-1.2*"

src_unpack() {
	unpack ${A}; cd ${S}
	# Fix compile of declaration_panel.c
	epatch ${FILESDIR}/${PN}-2.3.6-declaration_panel.patch
	# Don't copy SWI Prolog socket.so to /usr/bin (use -rpath instead)
	epatch ${FILESDIR}/${PN}-2.3.6-no-swi-socket.patch
	# Pass locations in as defines
	epatch ${FILESDIR}/${PN}-2.3.6-locations.patch
	# Default to use online help
	use doc || epatch ${FILESDIR}/${PN}-2.3.6-use-online-help.patch
	# Default not to pass -remote 'openURL(...)' to browsers
	epatch ${FILESDIR}/${PN}-2.3.6-no-remote-browser.patch
}

src_compile() {
	local SWI_PROLOG=$(best_version dev-lang/swi-prolog) || die "huh?"
	local SWI_PROLOG_VER=${SWI_PROLOG#dev-lang/swi-prolog-}
	local SWI_PROLOG_ARCH=${CHOST%%-*}-${CHOST#*-*-}
	local SWI_PROLOG_LIB=/usr/lib/pl-${SWI_PROLOG_VER}/lib/${SWI_PROLOG_ARCH}
	if use gnome; then local BROWSER=epiphany
	elif use kde; then local BROWSER=konqueror
	elif use firefox; then local BROWSER=firefox
	elif use mozilla; then local BROWSER=mozilla
	else local BROWSER=netscape; fi
	make \
		LDFLAGS="-Wl,-rpath,${SWI_PROLOG_LIB}" \
		CFLAGS="$(gtk-config --cflags) $CFLAGS -DHRP -DLAKATOS -DOP_DECS \
			-DDEFAULT_OOS_EXECUTABLE='\"/usr/bin/oos\"' \
			-DDEFAULT_HELP_DIR='\"/usr/share/doc/${PF}/html/help/\"' \
			-DDEFAULT_SCRIPT_DIR='\"/usr/$(get_libdir)/cogent/scripts/\"' \
			-DDEFAULT_OOS_CLASS_DIR'=\"/usr/$(get_libdir)/cogent/classes/\"' \
			-DDEFAULT_OOS_LIB_DIR='\"/usr/$(get_libdir)/cogent/oos/\"' \
			-DDEFAULT_WEB_BROWSER='\"${BROWSER}\"' \
			-DDEFAULT_SYS_INSTALL_HOME='\"/usr/$(get_libdir)/cogent/\"' \
			" \
		linux || die "make failed"
}

src_install() {
	make install BIN=${D}/usr/bin LIB=${D}/usr/$(get_libdir) \
		|| die "make install failed"
	rm -r ${D}/usr/lib/cogent/help
	use doc && dohtml -A xbm,gif,txt -r lib/help
	insinto /usr/share/pixmaps
	newins xbm/brain64.xpm cogent-brain64.xpm
	make_desktop_entry cogent Cogent cogent-brain64.xpm
}