nero-2.0.0.4.ebuild

nero-2.0.0.4.ebuild (text/plain), 3.02 KB, created by Jakub Moc (RETIRED) on 2006-01-11 05:49:33 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils rpm multilib

DESCRIPTION="Nero Burning ROM for Linux"
HOMEPAGE="http://www.nero.com/en/NeroLINUX.html" # nerolinux.nero.com coming soon...
NERO_RPM="nerolinux-${PV}-x86.rpm"
SRC_URI="ftp://ftp2.us.nero.com/${NERO_RPM}
	ftp://ftp6.de.nero.com/${NERO_RPM}
	http://httpdl3.nero.com/${NERO_RPM}
	http://httpdl6.nero.com/${NERO_RPM}"
LICENSE="Nero"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="mp3 vorbis shorten sox"
DEPEND=""
RDEPEND="virtual/libc
	|| ( x11-libs/libX11 virtual/x11 )
	=x11-libs/gtk+-1.2*
	mp3? ( media-sound/mpg123 media-sound/mp3info media-sound/lame )
	vorbis? ( media-sound/vorbis-tools media-sound/oggtst )
	shorten? ( media-sound/shorten media-sound/shntool media-sound/sox )
	sox? ( media-sound/sox )
	amd64? ( >=app-emulation/emul-linux-x86-gtklibs-2.0 )"

RESTRICT="nostrip nomirror"

src_unpack() {
	rpm_src_unpack
}

src_compile() { :; }

src_install() {
	cd "${WORKDIR}"

	dodir /opt/${PN}
	mv * "${D}/opt/${PN}"

	dodir /usr/bin
	dodir /usr/share/docs/${P}
	dodir /usr/share/${PN}/{desktop,pixmaps,sounds}

	dosym /opt/${PN}/usr/bin/nero /usr/bin/nero
	dosym /opt/${PN}/usr/share/nero/desktop/NeroLINUX.template \
	    /usr/share/${PN}/desktop/NeroLINUX.template
	dosym /opt/${PN}/usr/share/nero/pixmaps/nero.png \
	    /usr/share/${PN}/pixmaps/nero.png

	libdir=$(get_libdir)
	dodir /usr/${libdir}
	cd "${D}/opt/${PN}/usr/lib/"
	for x in *.so; do
	    dosym /opt/${PN}/usr/lib/${x} /usr/${libdir}/${x}
	done

	cd "${D}/opt/${PN}/usr/share/nero/"
	for x in {*.so,DosBootImage.ima,Nero.txt,CDROM.CFG}; do
	    dosym /opt/${PN}/usr/share/${x} /usr/share/${PN}/${x}
	done

	cd "${D}/opt/${PN}/usr/share/nero/docs"
	for x in {Manual.pdf,EULA,NEWS}; do
	    dosym /opt/${PN}/usr/share/nero/docs/${x} /usr/share/docs/${P}/${x}
	done

	cd "${D}/opt/${PN}/usr/share/nero/sounds"
	for x in *.wav; do
	    dosym /opt/${PN}/usr/share/nero/sounds/${x} /usr/share/${PN}/sounds/${x}
	done

	insinto /usr/share/applications
	doins ${FILESDIR}/nero.desktop
}

pkg_setup() {
	# This is a binary x86 package => ABI=x86
	has_multilib_profile && ABI="x86"
}

# TODO
# pkg_preinst() {
# 	check_license
# }

pkg_postinst() {
	einfo
	einfo "Please make sure that no hdX=ide-scsi option is passed"
	einfo "to your kernel command line."
	einfo "For setting up your burning device correctly you also"
	einfo "have to set read/write access to the devices that are"
	einfo "mapped to your disc drives, e.g.:"
	einfo "\tchmod a+rw /dev/hd*"
	einfo "\tchmod a+rw /dev/sg*"
	ewarn "This may be a security hole in multiuser environments!"
	einfo "A better approach is to add your user to the cdrom group, e.g.:"
	einfo "\tgpasswd -a <USER> cdrom"
	einfo
	einfo "NOTE: This is demo software, it will run for a trial"
	einfo "period only until unlocked with a serial number."
	einfo "See ${HOMEPAGE} for details."
	einfo
	einfo "Technical support for NeroLINUX is provided by CDFreaks"
	einfo "Linux forum at http://club.cdfreaks.com/forumdisplay.php?f=104"
	einfo
}