the ebuild

gnucash-1.7.8.ebuild (text/plain), 1.89 KB, created by Nick Fish on 2003-01-23 13:56:54 UTC

# Copyright 1999-2002 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit flag-o-matic

DESCRIPTION="A personal finance manager"
SRC_URI="http://download.sourceforge.net/${PN}/${P}.tar.gz"
HOMEPAGE="http://www.gnucash.org/"

KEYWORDS="x86 ppc"
SLOT="0"
LICENSE="GPL-2"
IUSE="nls postgres"

RDEPEND=">=gnome-base/gnome-libs-1.4.1.2-r1
	 >=dev-libs/libxml-1.8.3
	 >=gnome-extra/gtkhtml-0.14.0-r1
	 >=gnome-extra/gal-0.13-r1
	 >=gnome-extra/guppi-0.35.5-r2
	 >=gnome-base/gnome-print-0.21
	 postgres? ( dev-db/postgresql )"
DEPEND="${RDEPEND}
	>=sys-devel/perl-5
	>=dev-libs/slib-2.3.8
	>=dev-lang/swig-1.3_alpha4
	>=dev-libs/g-wrap-1.3.2
	<gnome-base/libglade-2
	media-libs/gdk-pixbuf
	<dev-util/guile-1.4.1
	gnome-base/libghttp
	nls? ( sys-devel/gettext )"

# won't configure with this
filter-flags -fomit-frame-pointer
# these flags to GCC interfere with G_INLINE_FUNC usage in this package
filter-flags "-fno-inline"
filter-flags "-finline-functions"


src_unpack() {
	unpack ${A}

	# With --enable-sql (use postgres), the gnucash 1.6.8 build process fails
	# when making in src/engine.  This should fix that.  --Chouser

	# not sure if  needed in 1.7.7+, someone using postgres should check --Fish
	cd ${S}/src/engine || die
	cp Makefile.am Makefile.am.old
	sed -e 's/^SUBDIRS *= */&. /' Makefile.am.old > Makefile.am || die
	cd ${S}
}

src_compile() {
	local myconf=""

	use nls      || myconf="--disable-nls"
	use postgres && myconf="$myconf --enable-sql"

	econf ${myconf}

	# prevent gcc warnings from breaking build on some systems when NLS disabled
	cd ${S}/src/gnome-utils
	cp Makefile Makefile.bak
	sed s/'-Werror '// Makefile.bak > Makefile || die
	cd ${S}

	make || die # Doesn't work with make -j 4 (hallski)
}

src_install() {
	export LIBRARY_PATH=${D}/usr/lib:${D}/usr/lib/gnucash
	einstall
	dodoc ABOUT-NLS AUTHORS COPYING ChangeLog HACKING NEWS README* TODO
}