Ebuild that applies suggested patch to fix xlaodimage related bug

electricsheep-2.6.3-r2.ebuild (text/plain), 2.12 KB, created by Chet McNeill on 2005-12-23 12:58:22 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/electricsheep/electricsheep-2.6.3-r1.ebuild,v 1.3 2005/12/20 22:24:27 spyderous Exp $

inherit eutils flag-o-matic kde-functions

DESCRIPTION="realize the collective dream of sleeping computers from all over the internet"
HOMEPAGE="http://electricsheep.org/"
SRC_URI="http://electricsheep.org/${P}.tar.gz"
IUSE="kde"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~sparc x86"

RDEPEND="|| ( ( x11-libs/libXv
			x11-libs/libICE
			x11-libs/libSM
		)
		virtual/x11
	)
	dev-libs/expat
	net-misc/curl
	media-gfx/xloadimage
	media-libs/jpeg
	media-libs/libpng
	media-libs/libsdl
	virtual/libc
	sys-libs/zlib"

DEPEND="${RDEPEND}
	|| ( ( x11-proto/xextproto
			x11-libs/libXt
		)
		virtual/x11
	)
	sys-apps/groff
	dev-lang/perl
	>=sys-apps/sed-4
	media-libs/libmpeg2
	sys-apps/gawk
	sys-apps/grep
	sys-devel/libtool"

src_unpack() {
	unpack ${A}
	# Detect PIC requirement from direct from compiler instead of
	# macro PIC.
	sed -i -e 's/def PIC/def __PIC__/' ${S}/mpeg2dec/src/cpu_accel.c
	epatch ${FILESDIR}/${P}-cflagsfix.patch
	epatch ${FILESDIR}/${P}-xloadimg.patch
}

# Also detects and ties in sys-libs/slang, media-libs/aalib media-libs/svgalib and nas
# if they exist on the user machine although these aren't deps.

src_install() {


	# prevent writing for xscreensaver
	sed -i "s/^install-data-local:$/install-data-local:\nmy-install-data-local:/" \
		Makefile || die "sed Makefile failed"

	# install the xscreensaver config file
	insinto /usr/share/xscreensaver/config
	doins electricsheep.xml

	make install DESTDIR=${D} || die "make install failed"

	dodir /usr/share/electricsheep
	if [ ! -f ${ROOT}/usr/share/electricsheep/electricsheep-uniqueid ]
	then
		${D}/usr/bin/uniqueid > ${D}/usr/share/electricsheep/electricsheep-uniqueid
	fi

	if use kde;
	then
		set-kdedir
		insinto /usr/share/applications
		doins ${FILESDIR}/${PN}.desktop
		insinto ${KDEDIR}//share/applnk/System/ScreenSavers
		doins ${FILESDIR}/${PN}.desktop
	fi

	# remove header files that are installed over libmpeg2
	rm -rf ${D}/usr/include
}