Proposed ebuild

gnucash-docs-4.8.ebuild (text/plain), 1.33 KB, created by Giuseppe Foti on 2021-10-05 04:47:48 UTC

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit cmake optfeature

DESCRIPTION="Documentation package for GnuCash"
HOMEPAGE="https://www.gnucash.org/"
SRC_URI="https://github.com/Gnucash/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2 FDL-1.1"
KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
LOCALES=( de it ja pt )
IUSE="${LOCALES[*]/#/l10n_}"

DEPEND="
	app-text/docbook-xml-dtd:4.5
	app-text/docbook-xsl-stylesheets
	app-text/rarian
	dev-libs/libxml2
	dev-libs/libxslt
"

src_prepare() {
	cmake_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-G"Unix Makefiles"
	)
	cmake_src_configure
}

src_compile() {
	:
}

src_install() {
	local doc_type my_lang

	for doc_type in manual guide; do
		for my_lang in C ${L10N}; do
			case $my_lang in
				# Both manual and guides translated
				C|de|it|pt) ;;
				ja) # Only guides translated
					if [[ ${doc_type} = "manual" ]] ; then
						elog "Help documentation hasn't been translated for $my_lang"
						elog "Will do English instead."
						continue
					fi
					;;
				*)
					die "Invalid locale: $my_lang"
					;;
			esac
			emake -C "${S}_build/${doc_type}/${my_lang}" DESTDIR="${D}" install
		done
	done

	einstalldocs
}

pkg_postinst() {
	optfeature "You need gnome-extra/yelp to view the docs." gnome-extra/yelp
}