Ebuild for the current development version for nmap. My patch has been merged upstream.

nmap-3.94_pre3.ebuild (text/plain), 2.00 KB, created by Meethune Bhowmick on 2005-12-06 16:29:25 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-3.93.ebuild,v 1.3 2005/11/29 21:23:00 hanno Exp $

inherit eutils flag-o-matic 

MY_P=${P/_pre3/ALPHA3}
MY_S=${S/%_pre3/ALPHA3}

DESCRIPTION="A utility for network exploration or security auditing"
HOMEPAGE="http://www.insecure.org/nmap/"
SRC_URI="http://download.insecure.org/nmap/dist/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc-macos ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="gtk ssl gksu"

DEPEND="virtual/libc
	dev-libs/libpcre
	=sys-devel/autoconf-2.13*
	gksu? ( x11-libs/gksu )
	gtk? ( =x11-libs/gtk+-2* )
	ssl? ( dev-libs/openssl )"

src_compile() {
	cd ${MY_S}
	use ppc-macos && filter-flags -fstrict-aliasing -O2
	# Fix the .desktop file
	sed 's:Icon=icon-network:Icon=nmap-logo-64.png:' -i nmapfe.desktop
	if useq gksu; then
		sed 's:^TryExec=.*$:TryExec=gksu :' -i nmapfe.desktop
		sed 's:^Exec=:Exec=gksudo :' -i nmapfe.desktop
	fi
	#Categories is missing a final semi-colon and eol
	echo ";" >> nmapfe.desktop
	
	econf \
		$(use_with gtk nmapfe) \
		$(use_with ssl openssl) || die
	emake -j1 || die
}

src_install() {
	cd ${MY_S}
	einstall -j1 nmapdatadir=${D}/usr/share/nmap install || die
	dodoc CHANGELOG HACKING INSTALL docs/README docs/*.txt
	dohtml docs/*.html
	if useq gtk; then
		dodir /usr/share/pixmaps
		insinto /usr/share/pixmaps
		doins ${FILESDIR}/nmap-logo-64.png 
	fi
}

pkg_postinst() {
	if useq gksu; then
		ewarn "Make sure your environment is properly set up to handle su-ed X applications."
		einfo "To do this add this to your sudoers file"
		einfo "(assuming you are in	the wheel group):"
		einfo
		einfo "    Defaults:%wheel         env_reset"
		einfo "    Defaults:%wheel         env_keep=DISPLAY"
		einfo "    Defaults:%wheel         env_keep+=XAUTHORITY"
		einfo 
		einfo "For more information please refer to the Gentoo FAQ item at"
		einfo "http://www.gentoo.org/doc/en/faq.xml#suinx"
	fi
}