quake1-darkplaces-20051129_beta2.ebuild

quake1-darkplaces-20051129_beta2.ebuild (text/plain), 2.39 KB, created by Paul Bredbury on 2005-11-29 20:31:08 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic games versionator

DESCRIPTION="Enhanced engine for iD Software's Quake"
HOMEPAGE="http://icculus.org/twilight/darkplaces/"

MY_PV=$(replace_version_separator 1 '' )
SRC_URI="http://icculus.org/twilight/darkplaces/files/darkplacesenginelinux${MY_PV}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa cdinstall cdsound dedicated opengl oss sdl"

RDEPEND="alsa? ( media-libs/alsa-lib )
	cdinstall? ( games-fps/quake1-data )
	opengl? ( virtual/opengl )
	sdl? ( media-libs/libsdl media-libs/sdl-mixer )"

DEPEND="${RDEPEND}
	app-arch/unzip"

S=${WORKDIR}/darkplaces

pkg_setup() {
	(use opengl || use sdl || use dedicated) || \
		die "At least one of the USE flags 'opengl', 'sdl' and 'dedicated' are required."

	games_pkg_setup
}

src_unpack() {
	unpack ${A}

	cd ${WORKDIR}
	unzip darkplacesenginesource${MY_PV}.zip || die "unzip failed"
	cd ${S}

	# Only CFLAGS optimization is the -march flag
	local MARCH=`get-flag -march`
	sed -i "s/CPUOPTIMIZATIONS=/CPUOPTIMIZATIONS=${MARCH}/" makefile.inc

	use cdsound || sed -i "s/cd_linux/cd_null/" makefile.inc

	# Default sound is alsa.
	if ! use alsa ; then
		if use oss ; then
			sed -i "s/DEFAULT_SNDAPI=ALSA/DEFAULT_SNDAPI=OSS/" \
				makefile
		else
			sed -i "s/DEFAULT_SNDAPI=ALSA/DEFAULT_SNDAPI=NULL/" \
				makefile
		fi
	fi
}

src_compile() {
	if use opengl ; then
		emake cl-release || die "emake cl-release failed"
	fi

	if use sdl ; then
		emake sdl-release || die "emake sdl-release failed"
	fi

	if use dedicated ; then
		emake sv-release || die "emake sv-release failed"
	fi
}

src_install() {
	if use opengl ; then
		games_make_wrapper darkplaces-glx \
			"${GAMES_BINDIR}/darkplaces-glx.bin" \
			"${GAMES_DATADIR}/quake1"
		newgamesbin darkplaces-glx darkplaces-glx.bin
	fi

	if use sdl ; then
		games_make_wrapper darkplaces-sdl \
			"${GAMES_BINDIR}/darkplaces-sdl.bin" \
			"${GAMES_DATADIR}/quake1"
		newgamesbin darkplaces-sdl darkplaces-sdl.bin
	fi

	if use dedicated ; then
		games_make_wrapper darkplaces-dedicated \
			"${GAMES_BINDIR}/darkplaces-dedicated.bin" \
			"${GAMES_DATADIR}/quake1"
		newgamesbin darkplaces-dedicated darkplaces-dedicated.bin
	fi

	dodoc darkplaces.txt ChangeLog todo
	prepgamesdirs
}

pkg_postinst() {
	einfo "Put the data files into ${GAMES_DATADIR}/quake1/id1"
	games_pkg_postinst
}