opera-8.51.20051114.ebuild

opera-8.51.20051114.ebuild (text/plain), 3.87 KB, created by Jeroen Roovers (RETIRED) on 2005-11-23 15:18:16 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/opera/opera-8.51.ebuild,v 1.3 2005/11/22 23:19:43 metalgod Exp $

inherit eutils versionator

DESCRIPTION="Opera web browser."
HOMEPAGE="http://www.opera.com/linux/"
RESTRICT="nomirror"

# Using versionator:
MY_PV="${PN}-$(replace_version_separator 2 -)"
MY_URI="mirror://opera/linux/$(get_major_version)$(get_version_component_range 2)/final/en/"
MY_EXT="en.tar.bz2"

SRC_URI="
	x86? ( static? ( ${MY_URI}i386/${MY_PV}.1-static-qt.i386-${MY_EXT} ) )
	x86? ( !static? ( ${MY_URI}i386/${MY_PV}.5-shared-qt.i386-${MY_EXT} ) )
	amd64? ( static? ( ${MY_URI}i386/${MY_PV}.1-static-qt.i386-${MY_EXT} ) )
	amd64? ( !static? ( ${MY_URI}i386/${MY_PV}.5-shared-qt.i386-${MY_EXT} ) )
	sparc? ( ${MY_URI}sparc/${MY_PV}.1-static-qt.sparc-${MY_EXT} )
	ppc? ( ${MY_URI}ppc/${MY_PV}.1-static-qt.ppc-${MY_EXT} )"

#	sparc? ( !static? ( ${MY_URI}/sparc/${MY_PV}.2-shared-qt.sparc-${MY_EXT} ) )
#	ppc? ( !static? ( ${MY_URI}/ppc/en/${MY_PV}.3-shared-qt.ppc-${MY_EXT} ) )

LICENSE="OPERA-8.50"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="static spell qt kde"

# Dependencies may be augmented later (see below).
DEPEND=">=sys-apps/sed-4
	amd64? ( sys-apps/linux32 )"

RDEPEND="virtual/x11
	>=media-libs/fontconfig-2.1.94-r1
	amd64? ( static? ( app-emulation/emul-linux-x86-xlibs )
	         !static? ( app-emulation/emul-linux-x86-qtlibs ) )
	!amd64? ( media-libs/libexif
	          x11-libs/openmotif
	          spell? ( app-text/aspell )
	          x86? ( !static? ( =x11-libs/qt-3* ) )
	          media-libs/jpeg )"

S=${WORKDIR}/${A/.tar.bz2/}

src_unpack() {
	unpack ${A}
	cd ${S}
	sed -i -e "s:config_dir=\"/etc\":config_dir=\"${D}/etc/\":g" \
	       -e "s:/usr/share/applnk:${D}/usr/share/applnk:g" \
	       -e "s:/usr/share/pixmaps:${D}/usr/share/pixmaps:g" \
	       -e "s:/usr/share/icons:${D}/usr/share/icons:g" \
	       -e "s:/etc/X11:${D}/etc/X11:g" \
	       -e "s:/usr/share/gnome:${D}/usr/share/gnome:g" \
	       -e "s:/opt/gnome/share:${D}/opt/gnome/share:g" \
	       -e 's:#\(OPERA_FORCE_JAVA_ENABLED=\):\1:' \
	       -e 's:#\(export LD_PRELOAD OPERA_FORCE_JAVA_ENABLED\):\1:' \
		   -e 's:read str_answer:return 0:' \
		   -e "s:/opt/kde:${D}/usr/kde:" \
		   -e "s:\(str_localdirplugin=\).*$:\1/opt/opera/lib/opera/plugins:" \
	       install.sh || die
}

src_compile() {
	true
}

src_install() {
	# Prepare installation directories for Opera's installer script.
	dodir /etc

	# Opera's native installer.
	if [ ${ARCH} = "amd64" ]; then
		linux32 ./install.sh --prefix="${D}"/opt/opera || die
	else
		./install.sh --prefix="${D}"/opt/opera || die
	fi

	# java workaround
	sed -i -e 's:LD_PRELOAD="${OPERA_JAVA_DIR}/libawt.so":LD_PRELOAD="$LD_PRELOAD"\:"${OPERA_JAVA_DIR}/libawt.so":' ${D}/opt/opera/bin/opera

	dosed /opt/opera/bin/opera
	dosed /opt/opera/share/opera/java/opera.policy

	# Install the icons
	insinto /usr/share/pixmaps
	doins images/opera.xpm

	# Install the menu entry
	insinto /usr/share/applications
	doins ${FILESDIR}/opera.desktop

	# Install a symlink /usr/bin/opera
	dodir /usr/bin
	dosym /opt/opera/bin/opera /usr/bin/opera

	# fix plugin path
	echo "Plugin Path=/opt/opera/lib/opera/plugins" >> ${D}/etc/opera6rc

	# enable spellcheck
	if use spell; then
		if use static; then
			DIR=$MY_PV.1
		else
			use sparc && DIR=$MY_PV.2 || DIR=$MY_PV.5
		fi
		echo "Spell Check Engine=/opt/opera/lib/opera/${DIR}/spellcheck.so" >> ${D}/opt/opera/share/opera/ini/spellcheck.ini
	fi

	#if use qt || use kde; then
	#	cd ${D}/opt/opera/bin
	#	epatch ${FILESDIR}/opera-qt.2.patch
	#fi
}

pkg_postinst() {
	einfo "For localized language files take a look at:"
	einfo "http://www.opera.com/download/languagefiles/index.dml?platform=linux"
	einfo
	einfo "To change the spellcheck language edit /opt/opera/share/opera/ini/spellcheck.ini"
	einfo "and emerge app-text/aspell-language."
}