pitivi-0.1.10.ebuild

pitivi-0.1.10.ebuild (text/plain), 1.47 KB, created by Ed Catmur on 2005-11-15 06:34:50 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils python

DESCRIPTION="A non-linear video editor using the GStreamer multimedia framework"
HOMEPAGE="http://www.pitivi.org"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND=">=dev-lang/python-2.3
	>=media-libs/gstreamer-0.8.8
	>=media-libs/gnonlin-0.2.2
	>=dev-python/pygtk-2.6.0
	>=dev-python/gnome-python-2.10.0
	>=dev-python/gst-python-0.8.2
	=sys-devel/automake-1.8*"
RDEPEND="${DEPEND}
	>=media-libs/gst-plugins-0.8.8
	>=media-plugins/gst-plugins-ffmpeg-0.8.4
	>=media-plugins/gst-plugins-xvideo-0.8.8
	>=media-plugins/gst-plugins-libpng-0.8.8"

pkg_setup() {
	if ! built_with_use dev-python/pygtk gnome; then
		eerror "Please merge dev-python/pygtk with 'gnome' in USE flags."
		die "Need glade support in pygtk!"
	fi
}

src_unpack() {
	unpack ${A}; cd ${S}
	# pitivi-48.png not shipped - does it even exist?
	sed -e 's/^\(Icon=\).*/\1gnome-multimedia/' -i ${PN}.desktop
	# fix import bug: put _add_pitivi_path() *after* _init_gobject_gtk_gst()
	sed -n -e '/^\s*_add_pitivi_path()/{h;n;p;x};p' -i bin/${PN}.in
	# replace broken py-compile with automake version
	cp /usr/share/automake-1.8/py-compile common/py-compile-destdir
}

src_install() {
	make install DESTDIR="${D}" || die "make install failed"
	insinto /usr/share/applications
	doins ${PN}.desktop
	dodoc AUTHORS ChangeLog NEWS README RELEASE
}