A proposed ebuild

v_sim-3.1.1.ebuild (text/plain), 2.78 KB, created by J.Borme on 2005-10-17 02:41:44 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils
DESCRIPTION="Displays atomic structures such as crystals, gain boudaries, molecules"
HOMEPAGE="http://www-drfmc.cea.fr/sp2m/L_Sim/V_Sim/index.en.html"
SRC_URI="http://www-drfmc.cea.fr/sp2m/L_Sim/V_Sim/download/${P}.tar.bz2"
LICENSE="CeCILL-1.1"
SLOT="0"
KEYWORDS="~x86 ~alpha"

# doc:   Adds developer documentation (${D}/usr/share/doc/${P}/APIreference/)
#        Example files are copied anyway (in ${D}/usr/share/doc/${P}/)
# debug: Adds console debug messages. This is really verbose.
IUSE="doc debug"

# V_sim should work with gtk 2.4, but has been tested with gtk 2.6.
RDEPEND=">=x11-libs/gtk+-2.6.8
		>=dev-libs/glib-2.4.5
		>=x11-libs/pango-1.8.1-r1
		>=media-libs/libpng-1.2
		virtual/opengl
		virtual/glu
		doc?  ( >=dev-util/gtk-doc-1.4-r1 )"
DEPEND="${RDEPEND}
		sys-apps/sed"
		
S="${WORKDIR}/${P}_package"

pkg_setup() {
	# Required
	check_license
}

src_compile() {
	if use doc ; then
		gtkdocize
	fi
	
	# The author follows Debian conventions, hence the example files and docs
	# end up in /usr/share/doc/${PN} instead of /usr/share/doc/${P}. We correct
	# this here.
	sed -e "s@/doc/.\${package}.@/doc/${P}@g" -e "s@/doc/\$PACKAGE@/doc/${P}@g" configure > configure.new
	mv -f configure.new configure
	chmod 755 configure
	
	# There's another occurrence: "usr/local/share/doc/${PN}", in
	# ${S}/src/visu_basic.c, this is a hardcoded default value in case the user
	# doesn't use the configure script. Since we use configure, we don't need
	# to modify this file.
	
	econf \
		`use_enable doc gtk-doc` \
		`use_enable debug debug-messages` || die "econf failed"
	HOME=${S} make || die "emake failed"
}

src_install() {
	make DESTDIR=${D} install || die
	# make install also copies example files and the documentation
}

pkg_postinst() {
	einfo "Example files are in /usr/share/doc/${P}/examples"
	einfo "(even with USE='-doc')"
	einfo ""
	einfo "The global v_sim config files are /usr/share/${PN}/"
	einfo "There are a few options which can only be configured in these files"
	einfo "and not through the UI. For example, one can specify different"
	einfo "colors for the box and the axes in the files, but in the UI one can"
	einfo "only change them together."
	einfo ""
	einfo "V_sim uses by default its own weird gtk skin. You can edit the"
	einfo "skin settings in /usr/share/${PN}/v_sim.rc"
	einfo "You can change the skin file used in the config file v_sim.par:"
	einfo "Go to the line 'config_skin[gtk]: V_Sim'. The argument may be:"
	einfo "'V_Sim', 'none' or the path to your own rc file. The keyword "
	einfo "'V_Sim' stands for the default rc file, /usr/share/v_sim/v_sim.rc"
	einfo "If you choose 'none' or if you comment the line, your current"
	einfo "gtk skin will be used."
}