eternal-lands-1.1.2-r1.ebuild

eternal-lands-1.1.2-r1.ebuild (text/plain), 4.24 KB, created by Bjørn Mogensen on 2005-10-13 23:19:12 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-rpg/eternal-lands/eternal-lands-1.1.2-r1.ebuild,v 1.2 2005/06/09 01:08:50 mr_bones_ Exp $

inherit games

TMP_PV=${PV%_p*}
DESCRIPTION="An online MMORPG written in C and SDL"
HOMEPAGE="http://www.eternal-lands.com"
SRC_URI="http://el.tfm.ro/el_${TMP_PV//.}_linux.zip
	ftp://ftp.berlios.de/pub/elc/elc_${TMP_PV//.}.tgz
	mapeditor? ( ftp://ftp.berlios.de/pub/elc/mapedit_${TMP_PV//.}.tgz )
	!nomusic? ( http://el.tfm.ro/el_music_101.zip )"

LICENSE="eternal_lands"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc nomusic mapeditor netthread"

RDEPEND="virtual/x11
	virtual/opengl
	>=media-libs/libsdl-1.2.5
	>=media-libs/sdl-net-1.2.5
	>media-libs/openal-20020127
	media-libs/libvorbis
	>=dev-libs/libxml2-2.6.7
	=media-libs/cal3d-0.10.0
	>=media-libs/libpng-1.2.8
	mapeditor? (>=x11-libs/gtk+-2.4)"

DEPEND="${RDEPEND}
	app-arch/unzip
	doc? ( >=app-doc/doxygen-1.3.8
		>=media-gfx/graphviz-1.10 )"

src_unpack() {
	OPTIONS="OPTIONS=-DDATA_DIR="\\\\\"${GAMES_DATADIR}/${PN}/\\\\\"""
	S_CLIENT="${WORKDIR}/elc"
	S_MAPEDITOR="${WORKDIR}/map_editor"
	BROWSER="mozilla"

	unpack ${A}
	use amd64 && OPTIONS="${OPTIONS} -DX86_64"
	use netthread && OPTIONS="${OPTIONS} -DNETWORK_THREAD"
	cd "${S_CLIENT}"
	sed \
		-e "s@CFLAGS=\$(PLATFORM) \$(CWARN) -O -ggdb -pipe@CFLAGS=${CFLAGS} @g"\
		-e "s@CXXFLAGS=\$(PLATFORM) \$(CXXWARN) -O -ggdb -pipe@CXXFLAGS=${CXXFLAGS} @g"\
		-e "s@OPTIONS=@${OPTIONS} @g" \
		Makefile.linux > Makefile \
		|| die "sed failed"
	sed \
		-e 's/#browser/browser/g' \
		-e "s/browser = mozilla/#browser = ${BROWSER}/g" \
		-e "s@#data_dir = /usr/local/games/el/@#data_dir = ${GAMES_DATADIR}/${PN}/@g" \
		el.ini > ../el.ini \
		|| die "sed failed"
	if use mapeditor; then
		cd ${S_MAPEDITOR}
		sed \
			-e "s@CFLAGS=@CFLAGS=${CFLAGS} @g" \
			-e "s@OPTIONS=@${OPTIONS} @g" \
			Makefile.linux > Makefile \
			|| die "sed failed"
		sed \
			-e "s@#data_dir = /usr/local/games/el/@#data_dir = ${GAMES_DATADIR}/${PN}/@g" \
			mapedit.ini > ../mapedit.ini \
			|| die "sed failed"
		mv browser.lst ../browser.lst
	fi
	cd ${WORKDIR}
	cp license.txt EULA || die "cp failed"
	cp -r ${S_CLIENT}/languages .
}

src_compile() {
	cd ${S_CLIENT}
	emake || die "emake failed"
	cp el.x86.linux.bin ../el.x86.linux.bin || die "cp failed"
	if use doc; then
		emake docs || die "Failed to create documentation, try with USE=-doc"
		mv ./docs/html/ ../client || die "Failed to move documentation directory"
	fi
	if use mapeditor; then
		cd ${S_MAPEDITOR}
		emake || die "emake failed"
		cp mapedit.x86.linux.bin ../mapedit.x86.linux.bin || die "cp failed"
	fi
}

src_install () {
	cd "${WORKDIR}"
	
	newgamesbin el.x86.linux.bin el || die "newgamesbin failed"
	if use mapeditor; then
		newgamesbin mapedit.x86.linux.bin el-mapedit \
			|| die "newgamesbin failed"
	fi

	doicon el_icon.png || die "doicon failed"

	dodoc EULA
	insinto "${GAMES_DATADIR}/${PN}"
	
	doins *.ini entrable.lst harvestable.lst \
		global_filters.txt e3dlist.txt \
		|| die "doins failed"

	if use mapeditor; then
		cp -r mapeditor ${D}/${GAMES_DATADIR}/${PN} || die "copy failed"
		doins browser.lst || die "doins failed"
	fi
	
	cp -R 2dobjects 3dobjects languages maps particles sound textures tiles\
	meshes animations actor_defs books skeletons\
		"${D}/${GAMES_DATADIR}/${PN}" \
		|| die "copy failed"
	
	if ! use nomusic; then
		cp -R music "${D}/${GAMES_DATADIR}/${PN}" || die "cp failed"
	fi

	if use doc; then
		dohtml -r "${WORKDIR}/client/"*
	fi
	if use mapeditor; then
		dohtml "${WORKDIR}/mapeditor.html"
		dohtml -r "${WORKDIR}/mapeditor"
	fi
	
	make_desktop_entry el "Eternal Lands" el_icon.png Game
	use mapeditor && \
		make_desktop_entry el-mapedit "Map editor" el_icon.png Game
	
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	echo
	einfo "To run the game: el"
	echo
	if use mapeditor; then
		einfo "To use the map editor: el-mapedit"
		einfo "Copy ${GAMES_DATADIR}/${PN}/mapedit.ini to ~/.elc/"
		einfo "to make per-user changes."
		echo
		einfo "To read an introduction to the map editor, read"
		einfo "/usr/share/doc/${PF}/html/mapeditor.html"
		echo
	fi
	if use doc; then
		einfo "The documentation for the client source can be found"
		einfo "in /usr/share/doc/${PF}/html/index.html"
		echo
	fi
}