rox-base/rox-configure-2005.10.ebuild

rox-configure-2005.10.ebuild (text/plain), 1.76 KB, created by Peter Hyman on 2005-10-04 06:14:16 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

#Module contributed by Peter Hyman
#need python utils to byte compile
inherit python

#this ebuild includes 4 programs
FONT_PN="Font"
FONT_PV=0.8
GAMMA_PN="Gamma"
GAMMA_PV=0.9.0
KEYBOARD_PN="Keyboard"
KEYBOARD_PV=0.9.3
MOUSE_PN="Mouse"
MOUSE_PV=0.8.3

DESCRIPTION="Configure is a suite of configuration utilities for ROX-Filer"
HOMEPAGE="http://roxos.sunsite.dk/dev-contrib/guido/Configure/"
SRC_URI="http://roxos.sunsite.dk/dev-contrib/guido/Configure/${FONT_PN}-${FONT_PV}.tar.bz2 
		http://roxos.sunsite.dk/dev-contrib/guido/Configure/${GAMMA_PN}-${GAMMA_PV}.tar.gz
		http://roxos.sunsite.dk/dev-contrib/guido/Configure/${KEYBOARD_PN}-${KEYBOARD_PV}.tar.gz
		http://roxos.sunsite.dk/dev-contrib/guido/Configure/${MOUSE_PN}-${MOUSE_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND=">=rox-base/rox-lib-1.9.13
		>=rox-base/rox-session-0.1.25"
S=${WORKDIR}

src_install() {
	# lots of code lifted from rox.eclass
	# Loop through all app names  
	for APPNAME in Font Gamma Keyboard Mouse; do
		# docs first
		if [ -d ${APPNAME}/Help/ ]; then
			#force docs into a subdir of ${PF}
			docinto ${APPNAME}
			for i in ${APPNAME}/Help/*; do 
				dodoc ${i}
			done
		fi

		# now copy sources over one by one
		insinto /usr/lib/rox
		doins -r ${APPNAME}
	
		find ${D}/usr/lib/rox/${APPNAME} -name 'AppRun' | xargs chmod 755 	>/dev/null 2>&1
		#create a script in bin to run the application from command line
		dodir /usr/bin/
		cat >${D}/usr/bin/${APPNAME} <<EOF
#!/bin/sh
exec /usr/lib/rox/${APPNAME}/AppRun "\$@"
EOF
		chmod 755 ${D}/usr/bin/${APPNAME}

		#now compile any and all python files
		python_mod_optimize ${D}/usr/lib/rox/${APPNAME} >/dev/null 2>&1
	done
}