[patch] fix.patch

0001-x11-wm-windowmaker-clean-up-NLS-static-libs-cross-co.patch (text/plain), 8.79 KB, created by David Michael on 2021-01-04 17:46:38 UTC

From a400a42f69d546a13a7538c792d9bb0c127894de Mon Sep 17 00:00:00 2001
From: David Michael <[e-mail]>
Date: Mon, 4 Jan 2021 12:46:17 -0500
Subject: [PATCH] x11-wm/windowmaker: clean up NLS, static-libs,
 cross-compiling

Closes: https://bugs.gentoo.org/746017
Closes: https://bugs.gentoo.org/763558
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: David Michael <[e-mail]>
---
 ...r1.ebuild => windowmaker-0.95.9-r2.ebuild} | 75 +++++++++++--------
 x11-wm/windowmaker/windowmaker-9999.ebuild    | 75 +++++++++++--------
 2 files changed, 86 insertions(+), 64 deletions(-)
 rename x11-wm/windowmaker/{windowmaker-0.95.9-r1.ebuild => windowmaker-0.95.9-r2.ebuild} (65%)

diff --git a/x11-wm/windowmaker/windowmaker-0.95.9-r1.ebuild b/x11-wm/windowmaker/windowmaker-0.95.9-r2.ebuild
similarity index 65%
rename from x11-wm/windowmaker/windowmaker-0.95.9-r1.ebuild
rename to x11-wm/windowmaker/windowmaker-0.95.9-r2.ebuild
index 79a742c81a1..29ea4bfb701 100644
--- a/x11-wm/windowmaker/windowmaker-0.95.9-r1.ebuild
+++ b/x11-wm/windowmaker/windowmaker-0.95.9-r2.ebuild
@@ -1,8 +1,8 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-inherit autotools desktop eutils
+inherit autotools desktop
 
 DESCRIPTION="The fast and light GNUstep window manager"
 HOMEPAGE="https://www.windowmaker.org/"
@@ -23,17 +23,18 @@ DEPEND="media-libs/fontconfig
 	gif? ( >=media-libs/giflib-4.1.0-r3 )
 	imagemagick? ( >=media-gfx/imagemagick-7:0= )
 	jpeg? ( virtual/jpeg:0= )
+	nls? ( virtual/libintl )
 	png? ( media-libs/libpng:0= )
 	tiff? ( media-libs/tiff:0 )
 	webp? ( media-libs/libwebp )
 	xinerama? ( x11-libs/libXinerama )
 	xrandr? ( x11-libs/libXrandr )"
-RDEPEND="${DEPEND}
-	nls? ( >=sys-devel/gettext-0.10.39 )"
+RDEPEND="${DEPEND}"
+BDEPEND="nls? ( >=sys-devel/gettext-0.10.39 )"
 
 S=${WORKDIR}/${P/windowm/WindowM}
 
-DOCS=( AUTHORS BUGFORM BUGS ChangeLog INSTALL INSTALL-WMAKER FAQ
+DOCS=( AUTHORS BUGFORM BUGS ChangeLog INSTALL-WMAKER FAQ
 	NEWS README README.definable-cursor README.i18n TODO )
 PATCHES=( "${FILESDIR}"/${PN}-0.95.8-configure_default_search_paths.patch )
 
@@ -44,38 +45,48 @@ src_prepare() {
 			sed -i -e "s|/usr/local/GNUstep/Applications/WPrefs.app|${EPREFIX}/usr/bin/|g;" "$file" || die
 			sed -i -e "s|/usr/local/share/WindowMaker|${EPREFIX}/usr/share/WindowMaker|g;" "$file" || die
 			sed -i -e "s|/opt/share/WindowMaker|${EPREFIX}/usr/share/WindowMaker|g;" "$file" || die
-		fi;
-	done;
+		fi
+	done
 
 	default
 	eautoreconf
 }
 
 src_configure() {
-	local myconf
-
-	# image format types
-	myconf="$(use_enable imagemagick magick) $(use_enable jpeg) $(use_enable gif) $(use_enable png) $(use_enable tiff) $(use_enable webp) $(use_enable xpm)"
-
-	# non required X capabilities
-	myconf="${myconf} $(use_enable modelock) $(use_enable xrandr randr) $(use_enable xinerama)"
-
+	local -a myeconfargs=(
+		# image format types
+		$(use_enable gif)
+		$(use_enable imagemagick magick)
+		$(use_enable jpeg)
+		$(use_enable png)
+		$(use_enable tiff)
+		$(use_enable webp)
+		$(use_enable xpm)
+
+		# optional X capabilities
+		$(use_enable modelock)
+		$(use_enable xinerama)
+		$(use_enable xrandr randr)
+	)
+
+	# NLS depends on whether LINGUAS is empty
 	if use nls; then
-		[[ -z $LINGUAS ]] && export LINGUAS="$(ls po/*.po | sed 's:po/\(.*\)\.po$:\1:' | xargs)"
+		myeconfargs+=( LINGUAS="${LINGUAS:-$(cd po; x=(*.po); echo ${x[*]%.po})}" )
 	else
-		myconf="${myconf} --disable-locale"
+		myeconfargs+=( LINGUAS= )
 	fi
 
-	# default settings with $myconf appended
 	econf \
+		--localedir="${EPREFIX}"/usr/share/locale \
 		--sysconfdir="${EPREFIX}"/etc/X11 \
-		--with-x \
+		--disable-static \
 		--enable-usermenu \
+		--with-{incs,libs}-from= \
 		--with-pixmapdir="${EPREFIX}"/usr/share/pixmaps \
-		--localedir="${EPREFIX}"/usr/share/locale \
-		${myconf}
+		--with-x \
+		"${myeconfargs[@]}"
 
-	pushd ../WindowMaker-extra-0.1 || die
+	pushd ../WindowMaker-extra-0.1 &>/dev/null || die
 	econf
 }
 
@@ -83,26 +94,26 @@ src_compile() {
 	emake
 
 	# WindowMaker Extra Package (themes and icons)
-	pushd ../WindowMaker-extra-0.1 || die
-	emake
+	emake -C ../WindowMaker-extra-0.1
 }
 
 src_install() {
 	default
 
 	# WindowMaker Extra
-	pushd ../WindowMaker-extra-0.1 || die
-	emake DESTDIR="${D}" install
-
-	newdoc README README.extra
+	emake -C ../WindowMaker-extra-0.1 DESTDIR="${D}" install
+	newdoc ../WindowMaker-extra-0.1/README README.extra
 
 	# create wmaker session shell script
-	echo "#!/usr/bin/env bash" > wmaker
-	echo "${EPREFIX}/usr/bin/wmaker" >> wmaker
-	exeinto /etc/X11/Sessions/
-	doexe wmaker
+	exeinto /etc/X11/Sessions
+	newexe - wmaker <<- EOF
+	#!/usr/bin/env bash
+	${EPREFIX}/usr/bin/wmaker
+	EOF
 
 	insinto /usr/share/xsessions
 	doins "${FILESDIR}"/wmaker.desktop
 	make_desktop_entry /usr/bin/wmaker
+
+	find "${ED}" -type f -name '*.la' -delete || die
 }
diff --git a/x11-wm/windowmaker/windowmaker-9999.ebuild b/x11-wm/windowmaker/windowmaker-9999.ebuild
index 9fabfa3d5f0..15020a5047c 100644
--- a/x11-wm/windowmaker/windowmaker-9999.ebuild
+++ b/x11-wm/windowmaker/windowmaker-9999.ebuild
@@ -1,8 +1,8 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-inherit autotools desktop eutils git-r3
+inherit autotools desktop git-r3
 
 DESCRIPTION="The fast and light GNUstep window manager"
 HOMEPAGE="https://www.windowmaker.org/"
@@ -24,15 +24,16 @@ DEPEND="media-libs/fontconfig
 	gif? ( >=media-libs/giflib-4.1.0-r3 )
 	imagemagick? ( >=media-gfx/imagemagick-7:0= )
 	jpeg? ( virtual/jpeg:0= )
+	nls? ( virtual/libintl )
 	png? ( media-libs/libpng:0= )
 	tiff? ( media-libs/tiff:0 )
 	webp? ( media-libs/libwebp )
 	xinerama? ( x11-libs/libXinerama )
 	xrandr? ( x11-libs/libXrandr )"
-RDEPEND="${DEPEND}
-	nls? ( >=sys-devel/gettext-0.10.39 )"
+RDEPEND="${DEPEND}"
+BDEPEND="nls? ( >=sys-devel/gettext-0.10.39 )"
 
-DOCS=( AUTHORS BUGFORM BUGS ChangeLog INSTALL INSTALL-WMAKER FAQ
+DOCS=( AUTHORS BUGFORM BUGS ChangeLog INSTALL-WMAKER FAQ
 	NEWS README README.definable-cursor README.i18n TODO )
 
 src_unpack() {
@@ -49,38 +50,48 @@ src_prepare() {
 			sed -i -e "s|/usr/local/GNUstep/Applications/WPrefs.app|${EPREFIX}/usr/bin/|g;" "$file" || die
 			sed -i -e "s|/usr/local/share/WindowMaker|${EPREFIX}/usr/share/WindowMaker|g;" "$file" || die
 			sed -i -e "s|/opt/share/WindowMaker|${EPREFIX}/usr/share/WindowMaker|g;" "$file" || die
-		fi;
-	done;
+		fi
+	done
 
 	default
 	eautoreconf
 }
 
 src_configure() {
-	local myconf
-
-	# image format types
-	myconf="$(use_enable imagemagick magick) $(use_enable jpeg) $(use_enable gif) $(use_enable png) $(use_enable tiff) $(use_enable webp) $(use_enable xpm)"
-
-	# non required X capabilities
-	myconf="${myconf} $(use_enable modelock) $(use_enable xrandr randr) $(use_enable xinerama)"
-
+	local -a myeconfargs=(
+		# image format types
+		$(use_enable gif)
+		$(use_enable imagemagick magick)
+		$(use_enable jpeg)
+		$(use_enable png)
+		$(use_enable tiff)
+		$(use_enable webp)
+		$(use_enable xpm)
+
+		# optional X capabilities
+		$(use_enable modelock)
+		$(use_enable xinerama)
+		$(use_enable xrandr randr)
+	)
+
+	# NLS depends on whether LINGUAS is empty
 	if use nls; then
-		[[ -z $LINGUAS ]] && export LINGUAS="$(ls po/*.po | sed 's:po/\(.*\)\.po$:\1:' | xargs)"
+		myeconfargs+=( LINGUAS="${LINGUAS:-$(cd po; x=(*.po); echo ${x[*]%.po})}" )
 	else
-		myconf="${myconf} --disable-locale"
+		myeconfargs+=( LINGUAS= )
 	fi
 
-	# default settings with $myconf appended
 	econf \
+		--localedir="${EPREFIX}"/usr/share/locale \
 		--sysconfdir="${EPREFIX}"/etc/X11 \
-		--with-x \
+		--disable-static \
 		--enable-usermenu \
+		--with-{incs,libs}-from= \
 		--with-pixmapdir="${EPREFIX}"/usr/share/pixmaps \
-		--localedir="${EPREFIX}"/usr/share/locale \
-		${myconf}
+		--with-x \
+		"${myeconfargs[@]}"
 
-	pushd ../WindowMaker-extra-0.1 || die
+	pushd ../WindowMaker-extra-0.1 &>/dev/null || die
 	econf
 }
 
@@ -88,26 +99,26 @@ src_compile() {
 	emake
 
 	# WindowMaker Extra Package (themes and icons)
-	pushd ../WindowMaker-extra-0.1 || die
-	emake
+	emake -C ../WindowMaker-extra-0.1
 }
 
 src_install() {
 	default
 
 	# WindowMaker Extra
-	pushd ../WindowMaker-extra-0.1 || die
-	emake DESTDIR="${D}" install
-
-	newdoc README README.extra
+	emake -C ../WindowMaker-extra-0.1 DESTDIR="${D}" install
+	newdoc ../WindowMaker-extra-0.1/README README.extra
 
 	# create wmaker session shell script
-	echo "#!/usr/bin/env bash" > wmaker
-	echo "${EPREFIX}/usr/bin/wmaker" >> wmaker
-	exeinto /etc/X11/Sessions/
-	doexe wmaker
+	exeinto /etc/X11/Sessions
+	newexe - wmaker <<- EOF
+	#!/usr/bin/env bash
+	${EPREFIX}/usr/bin/wmaker
+	EOF
 
 	insinto /usr/share/xsessions
 	doins "${FILESDIR}"/wmaker.desktop
 	make_desktop_entry /usr/bin/wmaker
+
+	find "${ED}" -type f -name '*.la' -delete || die
 }
-- 
2.26.2