Ebuild for the 1.0.3 binary version

lastfm-player-bin-1.0.3.ebuild (text/plain), 1.78 KB, created by David Li on 2005-09-08 15:32:39 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="The Last.fm player allows you to listen to their internet radio which is tailored to your music profile"
HOMEPAGE="http://www.last.fm"
SRC_URI="http://83.142.226.211/player/LastfmLinux-${PV}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86"
IUSE="alsa"
RESTRICT="nomirror"

S="${WORKDIR}/Last.fm-${PV}"

RDEPEND="virtual/x11"

src_install() {
	local destination="/opt/lastfm-bin"
	dodir ${destination}
	exeinto ${destination}
	doexe player

	dodir ${destination}/data
	insinto ${destination}/data
	doins data/*

	dodir ${destination}/data/buttons
	insinto ${destination}/data/buttons
	doins data/buttons/*

	diropts -m0777
	dodir ${destination}/cache
	keepdir ${destination}/cache

	# make_wrapper is not doing what I want
	exeinto /usr/bin
	cmd_player="${destination}/player"
	if use alsa ; then
		cmd_player="/usr/bin/aoss ${cmd_player}"
	fi
	local tmpwrapper=$(emktemp)
	cat << EOF > "${tmpwrapper}"
#!/bin/sh
cd "${destination}"
exec ${cmd_player} "\$@"
EOF
	chmod go+rx "${tmpwrapper}"
	newexe "${tmpwrapper}" "lastfm-bin"

	newicon data/icon.png lastfm-bin.png
	make_desktop_entry lastfm-bin "Last.fm Player" lastfm-bin.png
}

pkg_postinst() {
	einfo "In order to use the Last.fm player with your mozilla based browser,"
	einfo "You must follow these steps:"
	einfo
	einfo " 1. Go to \"about:config\" using the location bar"
	einfo " 2. Right-click on the page.  Select \"New\" and then \"String\""
	einfo " 3. Type in the name field: \"network.protocol-handler.app.lastfm\""
	einfo " 4. Type in the value field: \"/usr/bin/lastfm-bin\""
	einfo
	einfo "If you experiance awkward fonts or widgets, you may consider"
	einfo "running \"qtconfig\" and change the settings"
}