media-gfx/fotoxx-20.16.ebuild (fix compressed, documentation, and metainfo files)

fotoxx-20.16.ebuild (text/plain), 1.99 KB, created by mehw on 2020-11-22 18:16:11 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit xdg-utils

DESCRIPTION="Program for improving image files made with a digital camera"
HOMEPAGE="https://kornelix.net/fotoxx20/fotoxx.html"
SRC_URI="https://kornelix.net/downloads/downloads/${P}.tar.gz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dvd ffmpeg heif jpeg2k map panorama raw"

# For required dependencies read doc/README, for required tools read
# data/userguide [INSTALLATION]. xdg-open (x11-misc/xdg-utils) is an
# alternative to firefox and chromium-browser. `grep '"which ' * -R`
# is helpful to report some required tools run via the shell.

DEPEND="
	media-libs/libpng
	media-libs/tiff
	media-libs/lcms:2
	media-libs/libchamplain[gtk]
	virtual/jpeg
	x11-libs/gtk+:3"
RDEPEND="${DEPEND}
	media-gfx/dcraw
	media-libs/exiftool
	x11-misc/xdg-utils
	x11-apps/xgamma
	x11-apps/xhost
	x11-terms/xterm
	dvd? ( app-cdr/dvd+rw-tools )
	ffmpeg? ( media-video/ffmpeg )
	heif? ( media-libs/libheif )
	jpeg2k? ( media-libs/openjpeg:2 )
	map? ( media-gfx/fotoxx-maps )
	panorama? ( media-gfx/hugin )
	raw? ( media-gfx/rawtherapee )"

S="${WORKDIR}/${PN}"

PATCHES=(
	"${FILESDIR}/${P}-documentation.patch"
	"${FILESDIR}/${P}-manual.patch"
)

DOCS=()
HTML_DOCS=()

src_install() {
	# For the Help menu items to work, *.html must be in /usr/share/doc/${PF},
	# and README, changelog, copyright, license, etc. must not be compressed.
	emake DESTDIR="${D}" install
	rm -f "${D}"/usr/share/doc/${PF}/*.man || die
	docompress -x /usr/share/doc
}

pkg_postinst() {
	elog
	elog "Please read the Help > User Guide for details. The source location is"
	elog "/usr/share/fotoxx/data/userguide and after running fotoxx a copy will"
	elog "be placed at /home/<user>/.fotoxx/userguide."
	elog
	elog "To play videos, in Tools > Preferences set 'Video File Play Command'."
	elog
	xdg_desktop_database_update
	xdg_mimeinfo_database_update
}

pkg_postrm() {
	xdg_desktop_database_update
	xdg_mimeinfo_database_update
}