Improved rxvt-unicode-5.3 ebuild

rxvt-unicode-5.3-r1.ebuild (text/plain), 1.80 KB, created by René Rhéaume (a.k.a. repzilon, rener) on 2005-08-28 09:22:49 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit flag-o-matic

DESCRIPTION="rxvt clone with XFT and Unicode support"
HOMEPAGE="http://software.schmorp.de/"
SRC_URI="http://dist.schmorp.de/rxvt-unicode/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="xgetdefault tabs minimal truetype"

RDEPEND="virtual/x11
	dev-lang/perl
	tabs? ( dev-perl/gtk2-perl )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/libtool"

pkg_setup() {
	filter-flags -mno-accumulate-outgoing-args
	replace-flags -Os -O2
}

src_unpack() {
	unpack ${A}
	cd ${S}
	local tdir=/usr/share/terminfo
	sed -i -e "s~@TIC@ \(etc/rxvt\)~@TIC@ -o ${D}/${tdir} \1~" doc/Makefile.in
	sed -i -e "s:-g -O3:${CFLAGS}:" configure
}

src_compile() {
	local myconf=
	if use minimal; then
		myconf="--enable-next-scroll --enable-utmp --enable-mousewheel --enable-xim --enable-font-styles"
	else
		myconf="--enable-everything --enable-ttygid --enable-256-color"
	fi
	# --enable-shared prevents building on uclibc-based systems :-(
	use elibc_uclibc && myconf="${myconf} --disable-shared"

	econf ${myconf} \
		--enable-smart-resize \
		$(use_enable truetype xft) \
		$(use_enable xgetdefault) \
		--disable-text-blink --disable-menubar || die

	# Yes, rxvt-unicode is broken when it comes to optimisation flags
	emake CFLAGS="${CXXFLAGS}" || die

	if useq tabs ; then
		sed -i -e 's/RXVT_BASENAME = "rxvt"/RXVT_BASENAME = "urxvt"/' \
			${S}/doc/rxvt-tabbed || die "tabs sed failed"
	fi
}

src_install() {
	make DESTDIR=${D} install || die

	dodoc README.FAQ Changes
	cd ${S}/doc
	dodoc README* changes.txt etc/*

	useq tabs && newbin rxvt-tabbed urxvt-tabbed
}

pkg_postinst() {
	einfo "urxvt now always uses TERM=rxvt-unicode so that the"
	einfo "upstream-supplied terminfo files can be used."
}