Improved rxvt-unicode-4.0 ebuild

rxvt-unicode-4.0-r2.ebuild (text/plain), 1.51 KB, created by René Rhéaume (a.k.a. repzilon, rener) on 2005-08-28 09:22:30 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit 64-bit eutils

IUSE="xgetdefault minimal truetype"

DESCRIPTION="rxvt clone with XFT and Unicode support"
HOMEPAGE="http://software.schmorp.de/"
SRC_URI="http://rxvt-unicode-dist.plan9.de/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

DEPEND="virtual/libc
	dev-util/pkgconfig
	sys-devel/libtool
	virtual/x11
	dev-lang/perl"

src_unpack() {
	unpack ${A}
	cd ${S}
	local tdir=/usr/share/terminfo
	sed -i -e "s~@TIC@ \(etc/rxvt\)~@TIC@ -o ${D}/${tdir} \1~" doc/Makefile.in
	64-bit && epatch ${FILESDIR}/${P}-64bit.patch
}

src_compile() {
	local myconf=
	if use minimal; then
		myconf="--enable-next-scroll --enable-utmp --enable-mousewheel --enable-xim --enable-font-styles"
	else
		myconf="--enable-everything --enable-ttygid --enable-256-color"
	fi
	# --enable-shared prevents building on uclibc-based systems :-(
	use elibc_uclibc && myconf="${myconf} --disable-shared"

	econf ${myconf} \
		--enable-smart-resize \
		$(use_enable truetype xft) \
		$(use_enable xgetdefault) \
		--disable-text-blink --disable-menubar || die

	# Yes, rxvt-unicode is broken when it comes to optimisation flags
	emake CFLAGS="${CXXFLAGS}" || die
}

src_install() {
	make DESTDIR=${D} install || die

	dodoc README.unicode Changes
	cd ${S}/doc
	dodoc README* changes.txt BUGS TODO etc/*
}

pkg_postinst() {
	einfo "urxvt now always uses TERM=rxvt-unicode so that the"
	einfo "upstream-supplied terminfo files can be used."
}