games-fps/nexuiz-1.2

nexuiz-1.2.ebuild (text/plain), 2.09 KB, created by Damien Thébault on 2005-08-25 04:59:10 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="a free deathmatch FPS based on the Quake I engine"
HOMEPAGE="http://www.nexuiz.com"
SRC_URI="mirror://sourceforge/${PN}/${PN}${PV/./}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="sdl dedicated"

RDEPEND="sdl? ( media-libs/libsdl )"
DEPEND="virtual/opengl
		app-arch/unzip
		media-libs/jpeg
		media-libs/libogg
		media-libs/libsdl
		media-libs/libvorbis
		sys-libs/zlib
		${RDEPEND}"

S="${WORKDIR}/nexuiz"

src_compile() {
	cd "${S}"
	unzip $(ls nexuizenginesource* | head -n 1)
	cd "darkplaces"

	make cl-release \
		CFLAGS_RELEASE="" OPTIM_RELEASE="" \
		CFLAGS_COMMON="${CFLAGS} -ffast-math" \
	|| die "failed building cl-release"

	if use sdl;	then
		make sdl-release \
			CFLAGS_RELEASE="" OPTIM_RELEASE="" \
			CFLAGS_COMMON="${CFLAGS} -ffast-math" \
		|| die "failed building sdl-release"
	fi

	if use dedicated; then
		make sv-release \
			CFLAGS_RELEASE="" OPTIM_RELEASE="" \
			CFLAGS_COMMON="${CFLAGS} -ffast-math" \
		|| die "failed building sv-release"
	fi
}

src_install() {
	exeinto ${GAMES_DATADIR}/${PN}
	doexe darkplaces/nexuiz-glx || die "failed installing binary"
	use sdl && ( doexe darkplaces/nexuiz-sdl || die "failed installing sdl binary" )
	use dedicated && ( doexe darkplaces/nexuiz-dedicated || die "failed installing dedicated server" )

	insinto ${GAMES_DATADIR}/${PN}/data
	doins data/* || die "failed installing data"
	doins sources/darkplaces/nexuiz.ico || die "failed installing icon"

	games_make_wrapper nexuiz-glx ./nexuiz-glx ${GAMES_DATADIR}/${PN}
	use sdl && games_make_wrapper nexuiz-sdl ./nexuiz-sdl ${GAMES_DATADIR}/${PN}
	use dedicated && games_make_wrapper nexuiz-ded ./nexuiz-dedicated ${GAMES_DATADIR}/${PN}

	if use sdl; then
		make_desktop_entry nexuiz-sdl "Nexuiz" \
		${GAMES_DATADIR}/${PN}/data/nexuiz.ico Game \
	        || die "failed creating desktop entry"
	else
		make_desktop_entry nexuiz-glx "Nexuiz" \
		${GAMES_DATADIR}/${PN}/data/nexuiz.ico Game \
	        || die "failed creating desktop entry"
	fi

	prepgamesdirs
}