graphviz-cairo-2.4.ebuild

graphviz-cairo-2.4.ebuild (text/plain), 1.49 KB, created by Ed Catmur on 2005-08-21 18:04:36 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="A renderer plugin for graphviz that uses x11-libs/cairo"
HOMEPAGE="http://www.graphviz.org/"
SRC_URI="http://www.graphviz.org/pub/graphviz/ARCHIVE/$P.tar.gz"

LICENSE="CPL-1.0"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND=">=x11-libs/cairo-0.5.1
	>=x11-libs/gtk+-2.7.0
	>=media-gfx/graphviz-2.3"

src_install() {
	make install DESTDIR="${D}"
	dodoc AUTHORS ChangeLog NEWS README
}

graphviz-plugins_generate_plugins_cache() {
	local GVLIBDIR="/usr/lib/graphviz"
	local GVCACHEDIR="/var/cache/graphviz"
	if [[ -d "$GVLIBDIR" ]]; then
		ebegin "Regenerating $GVCACHEDIR/config"
		if [[ ! -d "$GVCACHEDIR" ]]; then
			eerror "directory $GVCACHEDIR missing!"
			eend 1
			return 1
		fi
		if [[ -e "$GVCACHEDIR/config" ]]; then
			ebegin "Backing up old registry to $GVCACHEDIR/config.old"
			mv "$GVCACHEDIR/config" "$GVCACHEDIR/config.old"
			eend $?
		fi
		ebegin "Generating new registry"
		dot -V >/dev/null
		eend $?
		if [[ ! -e "$GVCACHEDIR/config" && -e "$GVCACHEDIR/config.old" ]]; then
			ebegin "Restoring old registry"
			mv "$GVCACHEDIR/config.old" "$GVCACHEDIR/config"
			eend $?
		fi
		[[ ! "$GVCACHEDIR/config" -ot "$GVLIBDIR" ]]; eend $?
	else
		ebegin "Removing $GVCACHEDIR"
		rm "$GVCACHEDIR/"{config,config.old,.keep} && rmdir "$GVCACHEDIR"
		eend $?
	fi
}

pkg_postinst() {
	graphviz-plugins_generate_plugins_cache
}

pkg_postrm() {
	graphviz-plugins_generate_plugins_cache
}