media-libs/libsixel ebuild with python support

libsixel-1.8.6.ebuild (text/plain), 1.70 KB, created by Horea Christian on 2020-09-20 00:02:07 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI="7"

PYTHON_COMPAT=( python3_7 )
DISTUTILS_OPTIONAL="python"
inherit bash-completion-r1 distutils-r1

DESCRIPTION="A lightweight, fast implementation of DEC SIXEL graphics codec"
HOMEPAGE="https://github.com/saitoha/libsixel"
SRC_URI="https://github.com/saitoha/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT public-domain"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~x86"
IUSE="curl gd gtk jpeg png python static-libs"

RDEPEND="curl? ( net-misc/curl )
	gd? ( media-libs/gd )
	gtk? ( x11-libs/gdk-pixbuf:2 )
	jpeg? ( virtual/jpeg:0 )
	png? ( media-libs/libpng:0 )
	python? ( ${PYTHON_DEPS} )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"
BDEPEND="python? ( ${PYTHON_DEPS} )"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

src_prepare() {
	default
	if use python; then
		cd "${S}/python"
		distutils-r1_src_prepare
	fi
}

src_configure() {
	econf \
		$(use_with curl libcurl) \
		$(use_with gd) \
		$(use_with gtk gdk-pixbuf2) \
		$(use_with jpeg) \
		$(use_with png) \
		$(use_enable static-libs static) \
		--with-bashcompletiondir=$(get_bashcompdir) \
		--disable-python

	if use python; then
		cd "${S}/python"
		distutils-r1_src_configure
	fi
}

src_compile() {
	default
	if use python; then
		cd "${S}/python"
		distutils-r1_src_compile
	fi
}

src_test() {
	emake test
	if use python; then
		cd "${S}/python"
		distutils-r1_src_test
	fi
}

src_install() {
	default
	use static-libs || find "${ED}" -name '*.la' -delete || die

	cd images
	docompress -x /usr/share/doc/${PF}/images
	docinto images
	dodoc egret.jpg map{8,16}.png snake.jpg vimperator3.png
	if use python; then
		cd "${S}/python"
		distutils-r1_src_install
	fi
}