ebuild for ivtv 0.3.7c

ivtv-0.3.7-r3.ebuild (text/plain), 3.18 KB, created by Shan Destromp on 2005-08-14 09:29:37 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils linux-mod

DESCRIPTION="ivtv driver for Hauppauge PVR[23]50 cards"
HOMEPAGE="http://205.209.168.201/~ckennedy/ivtv/"

MY_P="${P/_/-}c"
FW_VER="pvr48wdm_1.8.22037.exe"
HCWMAKOA_ROM="pvr150_2028_23053_whql.zip"

SRC_URI="
	http://www.ivtv.tv/releases/ivtv-0.3/${MY_P}.tgz
	ftp://ftp.shspvr.com/download/wintv-pvr_250-350/win9x-2k-xp_mpeg_wdm_drv/${FW_VER}
	http://hauppauge.lightpath.net/software/pvr150/${HCWMAKOA_ROM}"

#RESTRICT="nomirror"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86 ~amd64"

IUSE=""
S="${WORKDIR}/${MY_P}"

MODULE_NAMES="cx25840(ivtv:${S}/driver)
	ivtv(ivtv:${S}/driver)
	msp3400(ivtv:${S}/driver)
	saa7115(ivtv:${S}/driver)
	saa7127(ivtv:${S}/driver)
	tuner(ivtv:${S}/driver)
	tveeprom(ivtv:${S}/driver)
	wm8775(ivtv:${S}/driver)"

BUILD_TARGETS="all"
BUILD_PARAMS="KDIR=${KERNEL_DIR}"
CONFIG_CHECK="I2C_ALGOBIT VIDEO_DEV"

DEPEND="app-arch/unzip"

src_unpack() {
	unpack ${MY_P}.tgz

	if grep '^CONFIG_FB=' ${ROOT}${KV_DIR}/.config
	then
		MODULE_NAMES="${MODULE_NAMES} ivtv-fb(extra:${S}/driver)"
	fi

	convert_to_m ${S}/driver/Makefile2.6

	unzip ${DISTDIR}/${HCWMAKOA_ROM} */HcwMakoA.ROM -d ${S} >/dev/null 2>&1

}

src_compile() {
	cd ${S}/driver
	linux-mod_src_compile || die "failed to build kernel modules"

	cd ${S}/utils
	make KERNELDIR=${KERNEL_DIR} ||  die "build of utils failed"
}

src_install() {
	cd ${S}/utils
	dodir /lib/modules
	./ivtvfwextract.pl ${DISTDIR}/${FW_VER} \
		${D}/lib/modules/ivtv-fw-enc.bin \
		${D}/lib/modules/ivtv-fw-dec.bin


	insinto /lib/modules/
	doins ${S}/"050222 Amity2 2.0.28.23053 (WHQL Signed)"/"HcwMakoA.ROM"

	cd ${S}
	dodoc README doc/*
	cd ${S}/utils
	newdoc README README.utils
	dodoc README.mythtv-ivtv README.X11
	dodoc lircd-g.conf lircd.conf lircrc

	cd ${S}/utils
	#should work... no idea why its not
	#make KERNELDIR=${KERNEL_DIR} DESTDIR=${D} INSTALLDIR=/usr/bin install-sane || die "failed to install"
	newbin encoder ivtv-encoder
	newbin fwapi ivtv-fwapi
	newbin radio ivtv-radio
	newbin vbi ivtv-vbi
	newbin mpegindex ivtv-mpegindex
	dobin ivtvfbctl ivtvplay ivtvctl

	cd ${S}/driver
	linux-mod_src_install || die "failed to install modules"
}

pkg_postinst() {
	linux-mod_pkg_postinst

	einfo "You now have the driver for the Hauppauge PVR-[123]50 cards."
	einfo "Add ivtv to /etc/modules.autoload.d/kernel-2.X"
	echo
	einfo "To get the ir remote working, you'll need to emerge lirc"
	einfo "with the following set:"
	einfo "LIRC_OPTS=\"--with-x --with-driver=hauppauge --with-major=61 "
	einfo "	--with-port=none --with-irq=none\" emerge lirc"
	echo
	einfo "You can also add the above LIRC_OPTS line to /etc/make.conf for"
	einfo "it to remain there for future updates."
	echo
	einfo "To use vbi, you'll need a few other things, check README.vbi in the docs dir"
	echo
	einfo "The ptune* scripts have moved to media-tv/ivtv-ptune, emerge that to use those scripts"
	echo

	if [ -f "${ROOT}/lib/modules/`uname -r`/kernel/drivers/media/video/msp3400.ko" ] ; then
		ewarn "You have the msp3400 module that comes with the kernel. It isn't compatible"
		ewarn "with ivtv. You need to back it up to somewhere else, then run update-modules"
	fi
}