cairo-ocaml-0.0_pre20050808.ebuild

cairo-ocaml-0.0_pre20050808.ebuild (text/plain), 941 bytes, created by Ed Catmur on 2005-08-08 16:25:17 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit cvs eutils

DESCRIPTION="Objective Caml bindings for Cairo"
HOMEPAGE="http://cairographics.org/cairo-ocaml"
ECVS_SERVER="cvs.freedesktop.org:/cvs/cairo"
ECVS_MODULE="cairo-ocaml"
ECVS_CO_OPTS="-D ${PV#*_pre}"
ECVS_UP_OPTS="-dP ${ECVS_CO_OPTS}"
S="${WORKDIR}/${PN}"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc gtk svg"

RDEPEND=">=dev-lang/ocaml-3.08
	>=x11-libs/cairo-0.5.2
	svg? ( >=x11-libs/libsvg-cairo-0.1.5 )
	gtk? ( dev-ml/lablgtk )"

src_unpack() {
	cvs_src_unpack
	cd ${S}
	epatch ${FILESDIR}/${PN}-0.0_pre20050808-cairo-api.patch
	aclocal -I support || die "aclocal failed"
	autoconf || die "autoconf failed"
}

src_compile() {
	econf \
		$(use_with gtk) \
		|| die
	emake || die
	if use doc; then
		emake doc || die
	fi
}

src_install() {
	make install DESTDIR="${D}" || die
	dodoc README
}