caboodle-0.2.ebuild

caboodle-0.2.ebuild (text/plain), 1.26 KB, created by Ed Catmur on 2005-08-08 16:24:09 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games eutils

DESCRIPTION="Arrange the balls on the screen so that no lines cross"
HOMEPAGE="http://www.iki.fi/juri/caboodle/"
SRC_URI="http://www.helsinki.fi/~pakaste/store/dl/$PN/releases/$P.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND=">=x11-libs/gtk+-2.0
	x11-libs/cairo"
DEPEND="${RDEPEND}
	>=dev-ml/lablgtk-2.4.0_p20050701
	dev-ml/cairo-ocaml
	dev-lang/ocaml"

pkg_setup() {
	if ! built_with_use dev-ml/lablgtk glade; then
		eerror "lablgtk is missing glade support."
		eerror "Please add 'glade' to your USE flags, and re-emerge lablgtk."
		die "lablgtk needs glade support"
	fi
}

src_unpack() {
	unpack $P.tar.gz; cd ${S}
	sed -e 's!share/caboodle/caboodle.glade!share/games/caboodle/caboodle.glade!' -i src/$PN.ml
	sed -e '/caboodle.desktop/d;/update-desktop-database/d' -i Makefile
}

src_install() {
	make \
		PREFIX="${D}${GAMES_PREFIX}" \
		DESKTOPLOCATION=/usr/share/applications \
		install || die "make install failed"
	dodir "${GAMES_DATADIR}"
	mv "${D}${GAMES_PREFIX}/share/${PN}" "${D}${GAMES_DATADIR}/"
	rmdir "${D}${GAMES_PREFIX}/share"
	doicon share/$PN/$PN.svg
	make_desktop_entry $PN "Caboodle"
	dodoc NEWS README
}