sun-j2me-2.2.ebuild

sun-j2me-2.2.ebuild (text/plain), 1.75 KB, created by Ortwin Glueck on 2005-08-08 14:59:12 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit java-pkg

DESCRIPTION="Java 2 Micro Edition Wireless Toolkit for developing wireless applications"
HOMEPAGE="http://java.sun.com/products/j2mewtoolkit/"
SRC_URI="j2me_wireless_toolkit-${PV//./_}-linux-i386.bin"
LICENSE="sun-bcla-j2me"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc examples"
RESTRICT="fetch"
DEPEND=">=dev-java/sun-jaf-bin-1.0
        >=sun-javamail-bin-1.3"
RDEPEND=">=virtual/jdk-1.4.2"
S=${WORKDIR}

MY_FILE=${DISTDIR}/${A}

pkg_nofetch() {
	einfo "Please download ${A} from:"
	einfo "http://java.sun.com/products/sjwtoolkit/download-2_2.html"
	einfo "and move it to ${DISTDIR}"
}

src_unpack() {
	if [ ! -r ${MY_FILE} ]; then
		eerror "cannot read ${A}. Please check the permission and try again."
		die
	fi
	#extract compressed data and unpack
	dd bs=2048 if=${MY_FILE} of=install.zip skip=10 2>/dev/null || die
	unzip install.zip >/dev/null || die
	rm install.zip

	#Set the java-bin-path in some scripts
	for file in ktoolbar emulator mekeytool prefs utils wscompile defaultdevice
	do
		sed ${WORKDIR}/bin/${file} --in-place --expression \
			"s@pathtowtk=\$@pathtowtk=\`java-config --jdk-home\`\"/bin/\"@" ||die
	done
	
	#replace included jar files with local versions
	cd bin
	rm -f activation.jar
	java-pkg_jar-from sun-jaf-bin activation.jar
	rm -f mail.jar
	java-pkg_jar-from sun-javamail-bin mail.jar
}

src_install() {
	cd ${WORKDIR}
	insinto /opt/${P}
	exeinto /opt/${P}/bin
	dohtml *.html
	use doc && java-pkg_dohtml -r docs/*
	use examples && doins -r apps
	doins -r appdb bin lib wtklib
	fperms 755 /opt/${P}/bin/*
	fperms 644 /opt/${P}/bin/*.jar
}

pkg_postinst() {
	einfo "In order to use this software run /opt/${P}/bin/ktoolbar"
}