ming-0.3_beta1.ebuild

ming-0.3_beta1.ebuild (text/plain), 2.56 KB, created by Láďa Durchánek on 2005-08-07 14:07:29 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/ming/ming-0.2a-r1.ebuild,v 1.2 2005/02/13 13:59:46 eradicator Exp $

inherit eutils toolchain-funcs python

DESCRIPTION="A OpenSource library from flash movie generation"
HOMEPAGE="http://www.opaque.net/ming/"
#SRC_URI="http://www.opaque.net/ming/${P}.tar.gz"
SRC_URI="mirror://sourceforge/ming/ming-0.3beta1.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ppc ~ppc64 ~s390 ~sparc x86"
IUSE="python"

DEPEND="virtual/libc
	media-libs/libungif
	python? ( virtual/python
              dev-lang/swig )"

S=${WORKDIR}/ming-0.3beta1

src_unpack() {
	unpack ${A}
	cd ${S}
	#epatch ${FILESDIR}/${P}-fpic.patch
	epatch ${FILESDIR}/ming-0.2a-gentoo.diff
	sed -e 's,gcc -g -Wall,$(CC) $(CFLAGS),g' -i ${S}/py_ext/Makefile
	if useq 'ppc-macos'; then
		sed -e 's, -shared , -dynamiclib ,g' -i ${S}/src/Makefile
		cd ${S}/util
		epatch ${FILESDIR}/decompile5.c.diff
		epatch ${FILESDIR}/listswf.c.diff
	fi
}

src_compile() {
	emake CC="$(tc-getCC) -Wall -I. -I.. -fPIC" CFLAGS="${CFLAGS}" all static || die
	cd util
	emake CC="$(tc-getCC) -Wall -I. -I.. -fPIC -DNODECOMPILE" CFLAGS="${CFLAGS}" bindump hexdump listswf listfdb listmp3 listjpeg makefdb swftophp || die
	if use python; then
		cd ${S}/py_ext
		python_version
		my_python="python${PYVER}"
		PYLIBDIR="/usr/$(get_libdir)/python${PYVER}"
		PYINCDIR="/usr/include/python${PYVER}"
		if useq 'ppc-macos'; then
			SHLIBLDFLAGS="-dynamiclib"
		else
			SHLIBLDFLAGS="-shared"
		fi
		emake CC="$(tc-getCC) -Wall" CFLAGS="${CFLAGS}" \
			PYINCDIR="${PYINCDIR}" PYLIBDIR="${PYLIBDIR}" \
			SHLIBLDFLAGS="${SHLIBLDFLAGS}" \
			_mingcmodule.so
	fi
}

src_install() {
	dolib.so libming.so || die "lib.so"
	dolib.a libming.a || die "lib.a"
	insinto /usr/include
	doins src/ming.h || die "include"
	doins src/ming_config.h || die "include"
	exeinto /usr/$(get_libdir)/ming
	doexe util/{bindump,hexdump,listswf,listfdb,listmp3,listjpeg,makefdb,swftophp} || die "utils"
	dodoc CHANGES CREDITS README TODO
	newdoc util/README README.util
	newdoc util/TODO TODO.util
	if use python; then
		cd ${S}/py_ext
		python_version
		PYLIBDIR="/usr/$(get_libdir)/python${PYVER}"
		insinto ${PYLIBDIR}/site-packages
		doins _mingcmodule.so ming.py mingc.py
		newdoc README README.python
		newdoc TODO TODO.python
		newdoc INSTALL INSTALL.python
		dodoc test.py shape.py
	fi
}
pkg_postinst() {
	if use python; then
		python_version
		python_mod_compile /usr/$(get_libdir)/python${PYVER}/site-packages/ming.py
	fi
}