x11-misc/screenkey-1.0.ebuild

screenkey-1.0.ebuild (text/plain), 1.38 KB, created by mehw on 2020-05-24 11:05:05 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

# Basend on x11-misc/screenkey from src_prepare-overlay overlay

EAPI=7

PYTHON_COMPAT=( python3_{6,7,8} )

DISTUTILS_USE_SETUPTOOLS=rdepend
inherit distutils-r1 xdg-utils

DESCRIPTION="A screencast tool to display your keys inspired by Screenflick"
HOMEPAGE="https://www.thregr.org/~wavexx/software/screenkey/"

if [[ "${PV}" == *9999* ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://gitlab.com/screenkey/${PN}.git"
	KEYWORDS=""
else
	SRC_URI="https://www.thregr.org/~wavexx/software/${PN}/releases/${P}.tar.gz"
	KEYWORDS="~amd64"
fi

RESTRICT="mirror"
LICENSE="GPL-3+"
SLOT="0"
IUSE="mouse +selection"

BDEPEND="
	dev-python/python-distutils-extra[${PYTHON_USEDEP}]
	dev-python/setuptools-git[${PYTHON_USEDEP}]
"
RDEPEND="
	selection? ( x11-misc/slop )
	dev-python/pycairo[${PYTHON_USEDEP}]
	dev-python/pygobject[${PYTHON_USEDEP}]
	sys-devel/gettext
"

src_prepare() {
	sed -i.bck "s#share/doc/screenkey#share/doc/${P}#" setup.py || die
	xdg_environment_reset
	if use mouse; then
		eapply 	"${FILESDIR}/${P}-mouse.patch"
	fi
	default
}

python_install() {
	distutils-r1_python_install
	if use mouse; then
		insinto "/usr/share/images/${PN}"
		doins images/*
	fi
}

pkg_postinst() {
	xdg_icon_cache_update
	xdg_desktop_database_update
}

pkg_postrm() {
	xdg_icon_cache_update
	xdg_desktop_database_update
}