qimgv 9999 ebuild

qimgv-9999.ebuild (text/plain), 1.16 KB, created by Max64hh on 2020-05-13 12:11:16 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

if [[ ${PV} == *9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/easymodo/qimgv.git"
else
	SRC_URI="https://github.com/easymodo/qimgv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi
inherit cmake-utils xdg-utils

DESCRIPTION="A cross-platform image viewer with webm support, written in qt5"
HOMEPAGE="https://github.com/easymodo/qimgv"

LICENSE="GPL-3"
SLOT="0"
IUSE="exif kde +opencv video"

BDEPEND="
	virtual/pkgconfig
"
DEPEND="
	dev-qt/qtconcurrent:5
	dev-qt/qtcore:5
	dev-qt/qtgui:5[egl]
	dev-qt/qtwidgets:5
	dev-qt/qtimageformats:5
	exif? ( media-gfx/exiv2:= )
	opencv? ( media-libs/opencv )
	kde? ( kde-frameworks/kwindowsystem:5 )
	video? ( media-video/mpv[libmpv,opengl] )
"
RDEPEND="
	${DEPEND}
"

src_configure() {
	local mycmakeargs=(
		-DEXIV2=$(usex exif)
		-DOPENCV_SUPPORT=$(usex opencv)
		-DKDE_SUPPORT=$(usex kde)
		-DVIDEO_SUPPORT=$(usex video)
	)
	cmake-utils_src_configure
}

pkg_postinst() {
	xdg_icon_cache_update
	xdg_desktop_database_update
}

pkg_postrm() {
	xdg_icon_cache_update
	xdg_desktop_database_update
}