Synaptics cPad / USB TouchPad driver v1.2 ebuild

cpad-1.2.ebuild (text/plain), 1.02 KB, created by David Korth on 2005-07-16 20:31:18 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit linux-mod

DESCRIPTION="Kernel module for the Synaptics cPad and Synaptics USB Touchpad"
HOMEPAGE="http://www.personal.uni-jena.de/~p1stja/linux/cpad.html"
SRC_URI="http://www.personal.uni-jena.de/~p1stja/linux/${P/${PV}/2.6-v${PV}}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
S=${WORKDIR}/cpad-2.6

DEPEND="virtual/linux-sources"

BUILD_TARGETS="all"
MODULE_NAMES="cpad(drivers/usb/input:${S})"

pkg_setup() {
	linux-mod_pkg_setup

	if kernel_is 2 4; then
		die "${P} does not support building against kernel 2.4.x"
	fi

	if ! (linux_chkconfig_present USB); then
		eerror "${P} requires support for USB host controllers (CONFIG_USB)."
		die "CONFIG_USB support not detected"
	fi

	if ! (linux_chkconfig_present INPUT_EVDEV); then
		eerror "${P} requires support for the evdev interface (CONFIG_INPUT_EVDEV)."
		die "CONFIG_INPUT_EVDEV support not detected"
	fi

	BUILD_PARAMS="KSRC=${KV_DIR}"
}