rst2pdf-0.96.ebuild

rst2pdf-0.96.ebuild (text/plain), 2.80 KB, created by Andrea Cerisara on 2020-04-19 00:57:09 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{6,7,8} )

DISTUTILS_USE_SETUPTOOLS="rdepend"
inherit distutils-r1

DESCRIPTION="Tool for transforming reStructuredText to PDF using ReportLab"
HOMEPAGE="https://rst2pdf.org/ https://pypi.org/project/rst2pdf/"
SRC_URI="https://github.com/rst2pdf/rst2pdf/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="sphinx matplotlib test inkscape"

DEPEND="dev-python/docutils[${PYTHON_USEDEP}]
	dev-python/jinja[${PYTHON_USEDEP}]
	dev-python/pdfrw[${PYTHON_USEDEP}]
	dev-python/pygments[${PYTHON_USEDEP}]
	dev-python/reportlab[${PYTHON_USEDEP}]
	dev-python/setuptools[${PYTHON_USEDEP}]
	dev-python/six[${PYTHON_USEDEP}]
	dev-python/smartypants[${PYTHON_USEDEP}]
        dev-python/simplejson[${PYTHON_USEDEP}]
	dev-python/svglib[${PYTHON_USEDEP}]
	sphinx? ( dev-python/sphinx[${PYTHON_USEDEP}] )
	matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
	inkscape? ( media-gfx/inkscape  )
	test? ( dev-python/nose[${PYTHON_USEDEP}] dev-python/coverage[${PYTHON_USEDEP}]  )
"

RDEPEND="${DEPEND}"
DOCS=( CHANGES.rst doc/manual.rst doc/rst2pdf.rst )

python_test() {
	distutils_install_for_testing

	# tests using aafigure extension, which is not supported
	touch ${PN}/tests/input/test_aafigure.ignore
	touch ${PN}/tests/input/test_aafigure_extra.ignore
	touch ${PN}/tests/input/sphinx-issue257.ignore

	# tests with unknown md5 checksum
	touch ${PN}/tests/input/source.ignore
	touch ${PN}/tests/input/test_box_widths.ignore
	touch ${PN}/tests/input/test_docutils_math.ignore
	touch ${PN}/tests/input/test_issue_310_2.ignore
	touch ${PN}/tests/input/test_issue_311.ignore
	touch ${PN}/tests/input/test_issue_473.ignore
	touch ${PN}/tests/input/test_issue_83.ignore
	touch ${PN}/tests/input/sphinx-issue252.ignore
	touch ${PN}/tests/input/test_fancytitles.ignore
	touch ${PN}/tests/input/test_slides.ignore

	if ! use matplotlib ; then
		touch ${PN}/tests/input/test_issue_363.ignore
	fi

	if ! use inkscape ; then
		touch ${PN}/tests/input/test_inkscape.ignore
		touch ${PN}/tests/input/test_issue_239_2.ignore
	fi

	WITH_SPHINX_TESTS=""
	use sphinx && WITH_SPHINX_TESTS=" -i sphinxtest"

	PATH=${PATH}:${TEST_DIR}/scripts nosetests -vv -i regulartest ${WITH_SPHINX_TESTS} || die "Test suite failed under ${EPYTHON}"
}

pkg_postinst() {
	elog "rst2pdf can work with the following packages for additional functionality:"
	elog "   wordaxe                 - hyphenation support"
	elog "   aafigure                - ascii art to image conversion"
	elog "   xhtml2pdf               - html support"
	elog ""
	elog "These packages are not available in the portage tree yet. Please refer to the manual"
	elog "installed in /usr/share/doc/${PF}/ for more information."
}