app-misc/protege-3.1

protege-3.1.ebuild (text/plain), 2.35 KB, created by Christoph Brill (egore) (RESIGNED) on 2005-07-06 08:43:34 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils java-pkg

OWL_V=257

DESCRIPTION="a free, open source ontology editor and knowledge-base framework"
HOMEPAGE="http://protege.stanford.edu/"
SRC_URI="http://protege.stanford.edu/download/prerelease/protege-src-3.1.zip
		owl? ( http://protege.stanford.edu/plugins/owl/download/protege-owl-src-${OWL_V}.zip )"
# The standard extensions need jgo (http://www.nwoods.com/go/jgo.htm), which
# isn't open source of free. So we won't add them.
#http://protege.stanford.edu/download/prerelease/standard-extensions-src-3.1.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc jikes owl"

DEPEND="owl? ( >=virtual/jdk-1.5
				dev-java/jena
				dev-java/xerces
				dev-java/owlsyntax
				dev-java/kazuki
				dev-java/jcalendar
				dev-java/ekit-bin )
			|| ( >=virtual/jdk-1.4 )
		dev-java/javacc
		dev-java/ant
		jikes? ( dev-java/jikes )
		dev-java/junit
		=dev-java/jgoodies-looks-bin-1.2*"
RDEPEND="owl? ( >=virtual/jre-1.5 )
            || ( >=virtual/jre-1.4 )"

S=${WORKDIR}/Protege\ 3.1\ Beta

src_unpack() {
	unpack ${A}
	use owl && cp -r ${WORKDIR}/source2.0/* "${S}/src/"
	cd "${S}"
	echo "javacc.home=/usr/share/javacc" > local.properties
	if use owl; then
		epatch ${FILESDIR}/${P}-owlbuild.patch
	fi
	sed -i \
		-e "s:{javacc.home}/bin/lib:{javacc.home}/lib:" \
		-e "s:unicode_panel.jar:unicode.jar:" \
		-e "s:looks.jar:jgoodies-looks-bin.jar:" \
		build.xml \
		|| die "fixing build.xml failed"
	epatch ${FILESDIR}/${P}-Formatter.patch # otherwise fails with 1.5
	cd "${S}/lib"
	rm -f *.jar
	java-pkg_jar-from junit
	java-pkg_jar-from unicode-bin
	java-pkg_jar-from jgoodies-looks-bin
	if use owl; then
		java-pkg_jar-from jena
		java-pkg_jar-from xerces-2
		java-pkg_jar-from owlsyntax
		java-pkg_jar-from kazuki
		java-pkg_jar-from jcalendar
		java-pkg_jar-from ekit-bin
	fi
}

src_compile() {
	local antflags="jar"
	use doc && antflags="${antflags} javadocs"
	use jikes && antflags="${antflags} -Dbuild.compiler=jikes"
	use owl && antflags="${antflags} -lib $(java-config -p jena,xerces-2)"
	ant ${antflags} || die "compilation failed"
}

src_install() {
	java-pkg_dojar dist/${PN}.jar
	echo "java -jar /usr/share/protege/lib/protege.jar" > protege
	dobin protege
	use doc && java-pkg_dohtml -r docs/*
	#use source && java-pkg_dosrc dist/protege-src-3.1.zip
}