dev-java/jena-2.2

jena-2.2.ebuild (text/plain), 1.08 KB, created by Christoph Brill (egore) (RESIGNED) on 2005-07-05 06:19:16 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit java-pkg

DESCRIPTION="a Java framework for building Semantic Web applications"
HOMEPAGE="http://jena.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.zip"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc jikes source"

DEPEND="virtual/jdk
		dev-java/antlr
		dev-java/commons-logging
		dev-java/concurrent-util
		dev-java/icu4j
		dev-java/jakarta-oro
		dev-java/junit
		dev-java/log4j
		dev-java/xerces"
RDEPEND="virtual/jre"

S=${WORKDIR}/Jena-${PV}

src_unpack() {
	unpack ${A}
	cd "${S}/lib"
	rm -f *.jar
	java-pkg_jar-from junit
	java-pkg_jar-from concurrent-util
	java-pkg_jar-from icu4j
}

src_compile() {
	local antflags="jar"
	use doc && antflags="${antflags} javadoc"
	use jikes && antflags="${antflags} -Dbuild.compiler=jikes"
	ant ${antflags} || die "compilation failed"
}

src_install() {
	java-pkg_dojar lib/${PN}.jar
	use doc && java-pkg_dohtml -r docs/*
	use source && java-pkg_dosrc -r bldsrc/*
	dodoc copyright.txt README.txt ReleaseNotes.txt
}