Ebuild for app-text/htmldoc-1.9.8

htmldoc-1.9.8.ebuild (text/plain), 1.63 KB, created by Nuno Silva on 2020-03-13 14:03:03 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit toolchain-funcs xdg-utils

DESCRIPTION="Convert HTML pages into a PDF document"
HOMEPAGE="https://www.msweet.org/htmldoc/index.html"
SRC_URI="https://github.com/michaelrsweet/${PN}/releases/download/v${PV}/${P}-source.tar.gz"
IUSE="fltk ssl"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha amd64 ~arm ~hppa ia64 ppc ppc64 sparc x86"

RDEPEND=">=media-libs/libpng-1.4:0=
	virtual/jpeg:0
	fltk? (
		x11-libs/fltk:1
		x11-libs/libXpm
	)
	ssl? ( net-libs/gnutls )
	sys-libs/zlib"
DEPEND="${RDEPEND}
	ssl? ( virtual/pkgconfig )"

PATCHES=(
	# Remove the "Application" category.
	"${FILESDIR}/$P-desktop.patch"

	# Remove MAKEOPTS from recipes which invoke make
	"${FILESDIR}/$P-makeflags.patch"
)

src_prepare() {
	default

	# make sure not to use the libs htmldoc ships with
	rm -r jpeg png zlib || die 'failed to unbundle jpeg, png, and zlib'

	# Fix the documentation path in a few places. Some Makefiles aren't
	# autotoolized =(
	for file in configure doc/Makefile doc/htmldoc.man; do
		sed -i "${file}" \
			-e "s:/doc/htmldoc:/doc/${PF}/html:g" \
			|| die "failed to fix documentation path in ${file}"
	done

	# Enable verbose build log
	sed -i Makedefs.in -e '/^.SILENT:$/d' \
		|| die "failed to remove .SILENT target in Makedefs.in"
}

src_configure() {
	CC=$(tc-getCC) CXX=$(tc-getCXX)	DSTROOT="${D}" econf \
		$(use_with fltk gui) \
		$(use_enable ssl) $(use_enable ssl gnutls)
}

src_install() {
	emake DSTROOT="${D}" STRIPPROG="/bin/true" install
}

pkg_postinst() {
	xdg_mimeinfo_database_update
}

pkg_postrm() {
	xdg_mimeinfo_database_update
}