Main ebuild for maya 6.5

maya-6.5.ebuild (text/plain), 7.79 KB, created by Stefan Skotte on 2005-06-19 12:38:34 UTC

# Note that this ebuild requires you to set the MAYA_INSTALL_LOC environment
# variable to the location of your maya RPMS and documentation:
# MAYA_INSTALL_LOC=/mnt/cdrom/LINUX is default
#
# This directory should contain something files that look like this:

inherit rpm eutils

IUSE="bundled-libs"
S="${WORKDIR}"

DESCRIPTION="Alias Wavefront's Maya.  Commercial modeling and animation package."
HOMEPAGE="http://www.alias.com/eng/products-services/maya/index.shtml"

# Patches to download go into SRC_URI
#SRC_URI="myr_maya501_gold_linux_update.tgz myr_TechDocs.zip"
SRC_URI=""
RESTRICT="fetch nouserpriv"

# RPM versions within the tarballs which will get installed
AWCOMMON="6.3-1.i686"
AWCOMMON_SERVER="6.3-1.i686"
MAYA6_5="6.5-253.i686"
MAYA6_5_DOCS="docs-6.5-253.i686"

SLOT="6.5"

LICENSE="maya-6.5 mayadoc-6.5"

KEYWORDS="~x86 ~amd64"

DEPEND="app-arch/unzip"

RDEPEND="|| ( app-shells/tcsh app-shells/csh )
	 x86? ( >=sys-libs/lib-compat-1.3
	        !bundled-libs? ( =x11-libs/qt-3*
	                         >=sys-devel/gcc-3
	                         >=x11-libs/openmotif-2.1.30 ) )
	 amd64? ( app-emulation/emul-linux-x86-baselibs
	          app-emulation/emul-linux-x86-xlibs
	          app-emulation/emul-linux-x86-qtlibs )
	 virtual/jre
	 virtual/opengl"

pkg_nofetch() {
	einfo "You need to place the Maya 6 CD in the CD drive (we expect /mnt/cdrom)."
	einfo "If you don't use /mnt/cdrom or you have network installation files, then you need to set"
	einfo "the environment variable 'MAYA_INSTALL_LOC' to the directory containing AWCommon-6.3-1.i686.rpm,"
	einfo "AWCommon-server-6.3-1.i686.rpm, Maya6_5-6.5-253.i686.rpm, and Maya6_5-docs-6.5-253.i686.rpm "
	einfo
}

src_unpack() {
	einfo ${MAYA_INSTALL_LOC}
	if [ -z "${MAYA_INSTALL_LOC}" ]; then
		cdrom_get_cds AWCommon-${AWCOMMON}.rpm
		MAYA_INSTALL_LOC=${CDROM_ROOT}
	fi

	if [ ! -d "${MAYA_INSTALL_LOC}" ]; then
		eerror "MAYA_INSTALL_LOC is not set to a valid location.  ${MAYA_INSTALL_LOC} is not a directory."
		die "Failure finding maya install files."
	fi

	mkdir ${S}/RPMS
	cd ${S}/RPMS
	# Unpack downloaded tarballs containing RPMs

	einfo
	einfo "Unpacking RPM-archives. This could take a while, please be patient."
	einfo
	# rpm_unpack unpacks in ${WORKDIR} no matter what we try... so get it out of the way...
	cd ${S}
	einfo "Unpacking AWCommon-${AWCOMMON}.rpm"
	rpm_unpack ${MAYA_INSTALL_LOC}/AWCommon-${AWCOMMON}.rpm
	
	einfo "Unpacking AWCommon-server-${AWCOMMON_SERVER}.rpm"
	rpm_unpack ${MAYA_INSTALL_LOC}/AWCommon-server-${AWCOMMON_SERVER}.rpm
	
	einfo "Unpacking Maya6_5-${MAYA6_5}.rpm"
	rpm_unpack ${MAYA_INSTALL_LOC}/Maya6_5-${MAYA6_5}.rpm

	einfo "Unpacking Maya6_5-${MAYA6_5_DOCS}.rpm"
	rpm_unpack ${MAYA_INSTALL_LOC}/Maya6_5-${MAYA6_5_DOCS}.rpm

	mkdir ${S}/insroot
	mv ${S}/usr ${S}/insroot

	# Don't need their init script
	rm -rf etc

	cp -a ${MAYA_INSTALL_LOC}/README.html ${S}

	# Remove unneeded libs (provided by DEPEND).
	if ! use bundled-libs; then
		rm -f ${S}/insroot/usr/aw/COM/lib/libXm.so.2.1
		rm -f ${S}/insroot/usr/aw/maya6.5/lib/libgcc_s.so.1
		rm -f ${S}/insroot/usr/aw/maya6.5/lib/libstdc++.so.5.0.5

		# We keep this one because of possible C++ ABI changes...
		# Maya 6 was compiled with gcc 3.0
		# rm -f ${S}/insroot/usr/aw/maya6.0/lib/libqt.so.3

		rm -f ${S}/insroot/usr/aw/maya6.5/lib/libXm.so.2

	fi

}

src_install() {
	dohtml README.html

	cd ${S}/insroot
	cp -a . ${D}

	# What follows is modified from rpm -qp --scripts RPMS/AWCommon-5.3-5.i686.rpm
	for lmexec in lmcksum lmdiag lmdown lmhostid lmremove lmreread lmstat lmver; do
		dosym lmutil /usr/aw/COM/bin/${lmexec}
	done

	# We use our own Motif runtime unless USE=bundled-libs
	if use bundled-libs; then
		dosym libXm.so.2.1 libXm.so
		dosym libXm.so.2.1 libXm.so.2
	fi

	dosym COM /usr/aw/COM2
	# End rpm -qp --scripts RPMS/AWCommon-5.3-5.i686.rpm

	# What follows is modified from rpm -qp --scripts RPMS/Maya5_0-5.0.1-135.i686.rpm
	keepdir /var/flexlm
	fperms ugo+w /var/flexlm

	dosym maya6.5 /usr/aw/maya

	# The RPM puts these in /usr/local/bin
	keepdir /usr/bin
	dosym /usr/aw/maya6.5/bin/Maya6.5 /usr/aw/maya6.5/bin/maya
	for mayaexec in Render fcheck imgcvt maya; do
		dosym /usr/aw/maya6.5/bin/${mayaexec} /usr/bin/${mayaexec}
	done

	# fix tail argument ('tail -1' is deprecated soon)
	dosed "/tail -1/tail -n 1/" /usr/aw/maya6.5/bin/maya

	# We use our own gcc3 runtime unless USE=bundled-libs
	if use bundled-libs; then
		dosym libgcc_s.so.1 /usr/aw/maya6.5/lib/libgcc_s.so
		dosym libstdc++.so.5.0.5 /usr/aw/maya6.5/lib/libstdc++.so.5
		dosym libstdc++.so.5.0.5 /usr/aw/maya6.5/lib/libstdc++.so
	fi

	# update the mental ray configuration files in place
	dosed "/\[PREFIX\]/s//\/usr/" /usr/aw/maya6.5/mentalray/maya.rayrc
	dosed "/\[PREFIX\]/s//\/usr/" /usr/aw/maya6.5/bin/mayarender_with_mr
	dosed "/\[PREFIX\]/s//\/usr/" /usr/aw/maya6.5/bin/mentalrayrender
	dosed "/\[PREFIX\]/s//\/usr/" /usr/aw/maya6.5/bin/mayaexport_with_mr
	fperms 755 /usr/aw/maya6.5/bin/mayarender_with_mr /usr/aw/maya6.5/bin/mentalrayrender

	# links for pcw
	dosym /usr/aw/maya6.5/lib/libawcsprt.so.1 /usr/aw/maya6.5/lib/libawcsprt.so
	dosym /usr/aw/maya6.5/lib/libpcw_opa.so.1 /usr/aw/maya6.5/lib/libpcw_opa.so
	dosym /usr/aw/maya6.5/lib/libpcwfindkey.so.1 /usr/aw/maya6.5/lib/libpcwfindkey.so
	dosym /usr/aw/maya6.5/lib/libpcwxml.so.1 /usr/aw/maya6.5/lib/libpcwxml.so

	# End rpm -qp --scripts RPMS/Maya5_0-5.0.1-135.i686.rpm

	# Install init scripts
	exeinto /etc/init.d
	doexe ${FILESDIR}/maya-docs ${FILESDIR}/aw_flexlm 
	insinto /etc/conf.d
	newins ${FILESDIR}/aw_flexlm.conf.d aw_flexlm

	# Fix permissions
	find ${D}/usr/aw -type d -exec chmod 755 {} \;
}

pkg_postinst() {
	# What follows is modified from rpm -qp --scripts RPMS/Maya5_0-5.0.1-135.i686.rpm
	cp /etc/services /tmp/services.maya_save

    awk '/mi-ray/ { found++; print ; next } {print} END {if (0==found) print "mi-ray 7003/tcp" }' /tmp/services.maya_save >/etc/services

    cp /etc/services /tmp/services.maya_save

    awk '/mi-raysat/ { found++; print ; next } {print} END {if (0==found) print "mi-raysat 7103/tcp" }' /tmp/services.maya_save >/etc/services

	# update the magic file 
	if [ -e /usr/share/magic ]; then
		mv /usr/share/magic /tmp/magic.rpmsave
		awk '/Alias.Wavefront Maya files. begin/ {p=1} /Alias.Wavefront Maya files. end/ {p=2} {if (p==2) { p=0} else if (p==0) print }' /tmp/magic.rpmsave > /usr/share/magic
		cat /usr/aw/maya6.5/.tmpdata/awmagic >> /usr/share/magic;
		# get file to rebuild the cache 
		file -C > /dev/null 2>&1
		rm -Rf /usr/aw/maya6.5/.tmpdata/awmagic 2>&1 > /dev/null
	fi 

	# End rpm -qp --scripts RPMS/Maya5_0-5.0.1-135.i686.rpm

	einfo "There may be a more recent license for this workstation available on the Alias|Wavefront"
	einfo "web site. Please visit the following URL to check for updated licenses:"
	einfo "http://www.aliaswavefront.com/en/Community/Special/keys/maya/"
	einfo
	einfo "To install your key, either place aw.dat in /var/flexlm or run the following command from an X session:"
	einfo "/usr/aw/COM/bin/installKey -input /usr/aw/maya6.5/license_data/maya_prekey_data"
	einfo
	einfo "Two init scripts have been installed:"
	einfo "maya-docs is for the document server (help system)."
	einfo "aw_flexlm is for the license server"
	einfo

	einfo "Maya 6.x was compiled with gcc 3.0 and origionally linked against glibc 2.1.3.  If you intend to compile"
	einfo "plugins for Maya, you will need to 'emerge \=sys-devel/gcc-3.0*' and use gcc-config to switch compilers."
	einfo "The Maya SDK headers are located in /usr/aw/maya/include, and libs are in /usr/aw/maya/lib."
	einfo

	# http://www.highend2d.com/boards/showthreaded.php?Cat=&Board=linuxforum&Number=174726&page=&view=&sb=&o=
	ewarn "You should disable klipper, xfce4-clipman, and any other clipboard"
	ewarn "utilities as they have been shown to cause maya-5.0.1 to crash."
	ewarn "Feedback on whether or not this is still true ion Maya 6 would be"
	ewarn "appreciated at http://bugs.gentoo.org"
}