Update of Daniel's 'pose-3.5-r5.ebuild to accomodate new patch

pose-3.5-r5.ebuild (text/plain), 3.44 KB, created by Scott on 2005-06-17 17:46:24 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvs/personal/gentoo/portage/app-emulation/pose/pose-3.5-r5.ebuild,v 1.6 2005/06/15 16:36:31 dwc Exp $

inherit eutils

EMULATOR_SRC_FILE="emulator_src_${PV}.tar.gz"
EMULATOR_SRC_URL="https://www.developerpavilion.com/palmos/page.asp?page_id=365&tool_id=7"

ROM_RELEASE_FILE="PalmOS412_RelROMs.zip"
ROM_DEBUG_FILE="PalmOS412_DbgROMs.zip"
ROM_URL="https://www.developerpavilion.com/palmos/page.asp?page_id=365&tool_id=61"

SKIN_FILE="emulator-skins-19.tar.gz"
SKIN_URL="https://www.developerpavilion.com/palmos/page.asp?page_id=365&tool_id=7"

DESCRIPTION="Palm OS Emulator"
HOMEPAGE="http://www.palmos.com/dev/tools/emulator/"
SRC_URI="${EMULATOR_SRC_FILE}
	roms? ( ${ROM_RELEASE_FILE} ${ROM_DEBUG_FILE} )
	skins? ( ${SKIN_FILE} )"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="x86 -ppc"
RESTRICT="nomirror fetch"

IUSE="roms skins"
DEPEND=">=x11-libs/fltk-1.1.4"

S=${WORKDIR}/Emulator_Src_${PV}

pkg_nofetch() {
	einfo "Please download ${EMULATOR_SRC_FILE} from:"
	einfo ${EMULATOR_SRC_URL}
	einfo "(Emulator 3.5 - Unix .gz - Source Code)"
	einfo "and move the file to ${DISTDIR}"

	if use roms; then
		einfo "Please download ${ROM_RELEASE_FILE} and ${ROM_DEBUG_FILE} from:"
		einfo ${ROM_URL}
		einfo "(English and EFIGS Platform ROMs - Windows .zip - Release and Debug versions)"
		einfo "and move the files to ${DISTDIR}"
	fi

	if use skins; then
		einfo "Please download ${SKIN_FILE} from:"
		einfo ${SKIN_URL}
		einfo "(Palm OS Emulator Skins 1.9 - Unix .gz - Binaries)"
		einfo "and move the file to ${DISTDIR}"
	fi
}

src_unpack() {
	unpack ${A}

	cd ${S}
	epatch \
		${FILESDIR}/detect-fluid.diff \
		${FILESDIR}/separate-builddir.diff \
		${FILESDIR}/choose-gl.diff \
		${FILESDIR}/init-clipwidget.diff \
		${FILESDIR}/gcc-3.3_fix.diff.bz2 \
		${FILESDIR}/sub-recent-gcc-fltk.diff
		
	ebegin "Generating configure scripts"
        export WANT_AUTOCONF=2.5

	cd ${S}/BuildUnix
	aclocal || die "aclocal"
	automake --foreign || die "automake"
	autoconf || die "autoconf"

	eend $?

	# Package build scripts do not honor C[XX]FLAGS, will have to do corrections via sed here
	sed -i -e "s:-DPLATFORM_UNIX:-DFLTK_1_0_COMPAT -DPLATFORM_UNIX:" \
		-e "s:-O2:-O2 -fno-strict-aliasing:" configure

	cd ${S}
	mkdir install-fltk
	ln -s ${ROOT}/usr/include/fltk-1.1 install-fltk/include
	ln -s ${ROOT}/usr/lib/fltk-1.1 install-fltk/lib
	mkdir static-libs
	mkdir build-normal
#	mkdir build-profile

	cd ${S}/static-libs
	ln -sf `g++ -print-file-name=libstdc++.a` libstdc++.a
}

src_compile() {
	cd ${S}/build-normal
#	cd ${S}/BuildUnix
	LDFLAGS=-L${S}/static-libs ../BuildUnix/configure --prefix=/usr \
		--with-fltk=${S}/install-fltk \
		--disable-gl || die

	make || die

#	cd ${S}/build-profile
#	LDFLAGS=-L${S}/static-libs ../BuildUnix/configure --prefix=/usr \
#		--with-fltk=${S}/install-fltk \
#		--disable-gl --enable-palm-profile || die
#
#	make || die
}

src_install() {
	cd ${S}/build-normal
	dobin pose

#	cd ${S}/build-profile
#	newbin pose pose-profile

	cd ${S}/Docs
	dodoc *.txt *.rtf *.pdf
	dohtml *.html

	dodir /usr/share/pose/downloads
	dodir /usr/share/pose/roms
	dodir /usr/share/pose/skins

	if use roms; then
		einfo "Installing ROMs"
		insinto /usr/share/pose/roms
		doins ${WORKDIR}/*.rom
	fi

	if use skins; then
		einfo "Installing skins"
		insinto /usr/share/pose/skins
		doins -r ${WORKDIR}/Skins_v1.9
	fi

	cd ${S}/ROMTransfer/Source
	insinto /usr/share/pose/downloads
	doins *.prc
}