libticables-3.8.7.ebuild

libticables-3.8.7.ebuild (text/plain), 3.34 KB, created by Octavio Ruiz (Ta^3) on 2005-04-26 01:07:43 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils linux-info

DESCRIPTION="Link cables support for the TiLP calculator linking program"
HOMEPAGE="http://tilp.info/"
SRC_URI="mirror://sourceforge/tilp/${P}.tar.gz"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="x86 ~ppc ~amd64"
IUSE="usb debug nls serial parallel"

RDEPEND="virtual/libc
	nls? ( sys-devel/gettext )
	usb? ( dev-libs/libusb )"
#	serial? ( )

DEPEND="${RDEPEND}
	sys-devel/bison"

pkg_setup() {
	if ! use usb &&	! use serial && ! use parallel ; then
		eerror "You have not selected any link cable support"
		eerror "(usb, serial or paralell)"
		eerror "You are going to be unable to use \"${PN}\" properly!"
		ebeep
	fi

	if use parallel && ! linux_chkconfig_present TIPAR ; then
		eerror "You have chosen by selecting 'USE=parallel' to have"
		eerror "parallel cable support but you dont have CONFIG_TIPAR"
		eerror "inside your kernel configuration. Please enable parallel"
		eerror "link cable support inside your kernel config, found at:"
		echo
		eerror " Device Drivers"
		eerror "   Character devices"
		eerror "      <*> Texas Instruments parallel link cable support"
		echo
		eerror "and then recompile your kernel ..."
		die "parallel link cable support not detected"
	fi

# This condition should be made by the tiser module ebuild
#
#	if use serial && ! linux_chkconfig_present SERIAL_8250 ; then
#		eerror "You have chosen by selecting 'USE=serial' to have"
#		eerror "parallel cable support but you dont have CONFIG_SERIAL_8250"
#		eerror "inside your kernel configuration. Please enable serial ports"
#		eerror "support inside your kernel config, found at:"
#		echo
#		eerror " Device Drivers"
#		eerror "   Character devices"
#		eerror "      Serial drivers"
#		eerror "        <*> 8250/16550 and compatible serial support"
#		echo
#		eerror "and then recompile your kernel ..."
#		die "serial ports support not detected"
#	fi
}

src_compile() {
	local myconf

	myconf="${myconf} $(use_enable nls)"
	myconf="${myconf} $(use_enable debug logging)"
	# Make sure that usb kernel module support is not
	# used, its deprecated, not supported and Portage
	# Tree do not provide the external module.
	# Use libusb instead (USE=usb)
	myconf="${myconf} --disable-direct-usb"

	econf ${myconf} || die "econf died"
	emake || die "emake died"
}

src_install() {
	make install DESTDIR=${D}
	dodoc AUTHORS ChangeLog LOGO README
}

pkg_postinst() {
	if ! use usb ; then
		ewarn "In order to use \"${PN}\" with an USB/SilverLink cable, you"
		ewarn "need to compile it with USE=usb and then rebuild \"${PN}\""
		ewarn "Note that the use of direct-usb (tiusb) is depecrated"
		ewarn "Please read the file: \"/usr/share/doc/${PF}/README.gz\""
		ewarn "for more details."
		echo ""
	fi

	if ! use serial ; then
		ewarn "In order to use \"${PN}\" with a serial/BlackLink cable,"
		ewarn "you need to compile it with USE=serial and then rebuild"
		ewarn "\"${PN}\""
		ewarn "Please read the file: \"/usr/share/doc/${PF}/README.gz\""
		ewarn "for more details."
		echo ""
	fi

	if ! use parallel; then
		ewarn "In order to use \"${PN}\" with a parallel link cable you need to"
		ewarn "have CONFIG_TIPAR in your kernel config and select"
		ewarn "'USE=parallel' then rebuild \"${PN}\""
		ewarn "Please read the file: \"/usr/share/doc/${PF}/README.gz\""
		ewarn "for more details."
	fi
}