ebuild for telnet client only

netkit-telnet-0.17-r6.ebuild (text/plain), 1.85 KB, created by Grzegorz Chwesewicz on 2005-04-12 13:27:05 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/netkit-telnetd/netkit-telnetd-0.17-r6.ebuild,v 1.10 2005/04/03 11:24:19 hardave Exp $

inherit eutils

PATCHLEVEL=28
DESCRIPTION="Standard Linux telnet client and server"
HOMEPAGE="ftp://ftp.uk.linux.org/pub/linux/Networking/netkit/"
SRC_URI="ftp://ftp.uk.linux.org/pub/linux/Networking/netkit/netkit-telnet-${PV}.tar.gz
	http://ftp.debian.org/debian/pool/main/n/netkit-telnet/netkit-telnet_0.17-${PATCHLEVEL}.diff.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="alpha amd64 hppa ia64 mips ppc ppc64 sparc x86"
IUSE="build"

DEPEND=">=sys-libs/ncurses-5.2
	!net-misc/telnet-bsd"

S=${WORKDIR}/netkit-telnet-${PV}

src_unpack() {
	unpack ${A}
	cd ${S}
	# Patch: [0]
	# Gentoo lacks a maintainer for this package right now. And a 
	# security problem arose. While reviewing our options for how 
	# should we proceed with the security bug we decided it would be 
	# better to just stay in sync with debian's own netkit-telnet 
	# package. Lots of bug fixes by them over time which were not in 
	# our telnetd.
	epatch ${WORKDIR}/netkit-telnet_0.17-${PATCHLEVEL}.diff || die

	# Patch: [1]
	# after the deb patch we need to add a small patch that defines 
	# gnu source. This is needed for gcc-3.4.x (needs to be pushed 
	# back to the deb folk?)
	epatch ${FILESDIR}/netkit-telnetd-0.17-cflags-gnu_source.patch \
		|| die
}

src_compile() {
	./configure --prefix=/usr || die

	sed -i \
		-e "s:-pipe -O2:${CFLAGS}:" \
		-e "s:-Wpointer-arith::" \
		MCONFIG

	make SUB=telnet|| die
}

src_install() {
	dobin telnet/telnet || die
	#that's it if we're going on a build image
	use build && return 0

	doman telnet/telnet.1
	dodoc BUGS ChangeLog README
	dodoc ${FILESDIR}/net.issue.sample
	newdoc telnet/README README.telnet
	newdoc telnet/TODO TODO.telnet
}