xdtv-2.1.1.ebuild

xdtv-2.1.1.ebuild (text/plain), 4.73 KB, created by TGL on 2005-04-03 05:35:14 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit font

IUSE="alsa jpeg encode ffmpeg xvid lirc xinerama divx4linux \
	neXt Xaw3d mmx zvbi aqua_theme"
# For use.local.desc:
# media-tv/xdtv:aqua_theme - Adds the Aqua pixmaps theme for the GUI
# media-tv/xdtv:zvbi - Enable VBI Decoding Library for Zapping

DESCRIPTION="TV viewer with support for AVI recording and plugins"
HOMEPAGE="http://xawdecode.sourceforge.net/"

I18N_CA="libxdtv-i18n-ca-1.0.2"
I18N_EN="libxdtv-i18n-en-1.0.2"
I18N_ES="libxdtv-i18n-es-1.0.2"
I18N_FR="libxdtv-i18n-fr-1.0.2"
THEME_AQUA_EN="libxdtv-theme-aqua-en-1.0.2"
THEME_AQUA_ES="libxdtv-theme-aqua-es-1.0.2"
THEME_AQUA_FR="libxdtv-theme-aqua-fr-1.0.2"

DOWNLOADS_URL="mirror://sourceforge/xawdecode"
SRC_URI="${DOWNLOADS_URL}/${P}.tar.gz
	linguas_ca? ( 
		${DOWNLOADS_URL}/${I18N_CA}.tar.gz )	
	linguas_en? (
		${DOWNLOADS_URL}/${I18N_EN}.tar.gz
		aqua_theme? ( ${DOWNLOADS_URL}/${THEME_AQUA_EN}.tar.gz ) )
	linguas_es? ( 
		${DOWNLOADS_URL}/${I18N_ES}.tar.gz
		aqua_theme? ( ${DOWNLOADS_URL}/${THEME_AQUA_ES}.tar.gz ) )
	linguas_fr? ( 
		${DOWNLOADS_URL}/${I18N_FR}.tar.gz
		aqua_theme? ( ${DOWNLOADS_URL}/${THEME_AQUA_FR}.tar.gz ) )
	!linguas_ca? ( !linguas_es? ( !linguas_fr? ( !linguas_fr_ca? (
		${DOWNLOADS_URL}/${I18N_EN}.tar.gz
		aqua_theme? ( ${DOWNLOADS_URL}/${THEME_AQUA_EN}.tar.gz ) ) ) ) )"	

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86"

RDEPEND="virtual/x11
	zvbi? ( >=media-libs/zvbi-0.2.4 )
	neXt? ( x11-libs/neXtaw )
	Xaw3d? ( !neXt? ( x11-libs/Xaw3d ) )
	divx4linux? ( >=media-libs/divx4linux-20030428 )
	ffmpeg? ( >=media-video/ffmpeg-0.4.7 )
	xvid? ( =media-libs/xvid-1* )
	encode? ( >=media-sound/lame-3.93 )
	jpeg? ( media-libs/jpeg )
	lirc? ( app-misc/lirc )
	alsa? ( >=media-libs/alsa-lib-0.9 )"

FONT_S="${S}/font"
FONT_SUFFIX="pcf.gz"

extension_iter() {
	local my_a
	for my_a in ${A} ; do
		my_a=${my_a%%.tar.gz}
		if [ -z ${my_a/libxdtv*/} ] ; then
			eval ${1} ${my_a} || die "${1}(${my_a}) failed."
		fi
	done
}

extension_compile() {
	einfo "Building ${1}"
	cd ${WORKDIR}/${1} \
		&& econf \
		&& make
}

extension_install() {
	einfo "Installing ${1}"
	cd ${WORKDIR}/${1} \
		&& make DESTDIR=${D} install
}

pkg_setup() {
	use linguas_ca && use aqua_theme \
		&& einfo "Sorry, but the Aqua theme is not available in Catalan." \
		&& einfo "Only the default theme will be installed."
}

src_unpack() {
	unpack ${A}
	# Disable font installation
	sed -i '/^install:/,/^$/s:^\t:#:p' ${S}/font/Makefile.in
	# Disable /usr/share/xdtv/icons/* installation
	sed -i '/^install-data-local:/,${\:share/xdtv/icons:d}' ${S}/Makefile.in
}

src_compile() {
	# Makes the xaw widgets choice deterministic
	local xawconf="--disable-xaw95 --disable-xawm"
	if use neXt ; then
		use Xaw3d && ewarn "Both \"neXt\" and \"Xaw3d\" found in USE. Will use neXtaw widgets."
		xawconf="${xawconf} --enable-nextaw --disable-xaw3d"
	elif use Xaw3d ; then 
		xawconf="${xawconf} --disable-nextaw --enable-xaw3d"
	else
		xawconf="${xawconf} --disable-nextaw --disable-xaw3d"
		ewarn "If you want a better GUI toolkit, enable either \"neXt\" or \"Xaw3d\" USE flags."
	fi

	econf ${xawconf} \
		`use_enable divx4linux` \
		`use_enable alsa` \
		`use_enable jpeg` \
		`use_enable lirc` \
		`use_enable ffmpeg` \
		`use_enable xvid` \
		`use_enable xinerama` \
		`use_enable mmx` \
		`use_enable zvbi` \
		--enable-pixmaps \
		--disable-cpu-detection \
		|| die "Configuration failed."

	emake OPT="${CFLAGS}" PERF_FLAGS="${CFLAGS}" || die "Compilation failed."

	# Build the extensions (i18n and theme libraries)
	extension_iter extension_compile
}

src_install() {
	make DESTDIR=${D} install || die "Installation failed."

	# .desktop file and default icon
	insinto /usr/share/applications
	doins gentoo/xdtv.desktop
	insinto /usr/share/icons
	doins ${S}/src/xdtv.xpm

	# Install the icons in the hicolor theme
	insinto /usr/share/icons/hicolor/48x48/apps/
	newins ${S}/xdtv-48.png xdtv.png
	insinto /usr/share/icons/hicolor/32x32/apps/
	newins ${S}/xdtv-32.png xdtv.png
	insinto /usr/share/icons/hicolor/16x16/apps/
	newins ${S}/xdtv-16.png xdtv.png

	# Install the led-fixed font with font.eclass
	gzip font/led-fixed.pcf
	font_src_install

	# Install documentation
	dodoc COPYING ChangeLog AUTHORS INSTALL
	dodoc FAQ* README.* TODO lisez-moi* libavc-rate-control.txt
	dodoc xdtvrc.sample lircrc.*.sample
	docinto alevt
	dodoc alevt/README alevt/ReadmeGR alevt/CHANGELOG alevt/COPYRIGHT

	# Install the extensions (i18n and theme libraries)
	extension_iter extension_install
}

pkg_postinst() {
	echo
	einfo "Please note that this ebuild created a suid-binary:"
	einfo "/usr/bin/xdtv_v4l-conf"
	echo
	einfo "The OSD font has moved. You probably should add"
	einfo "this path to your X configuration:"
	einfo "/usr/share/fonts/${PN}"
	echo
}