irrlicht-0.9.ebuild

irrlicht-0.9.ebuild (text/plain), 1.35 KB, created by SpanKY on 2005-03-28 22:12:06 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-games/irrlicht/irrlicht-0.7.1.ebuild,v 1.3 2005/03/29 02:43:47 vapier Exp $

inherit eutils

DESCRIPTION="open source high performance realtime 3D engine written in C++"
HOMEPAGE="http://irrlicht.sourceforge.net/"
SRC_URI="mirror://sourceforge/irrlicht/${P}.zip
	mirror://sourceforge/irrlicht/${P}.zip"

LICENSE="ZLIB"
SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE="doc"

RDEPEND="media-libs/jpeg
	sys-libs/zlib
	virtual/opengl
	virtual/x11"
DEPEND="${RDEPEND}
	app-arch/unzip"

src_unpack() {
	unpack ${A}
	cd "${S}"/source
	unzip -qo source.zip || die "unpacking source.zip"
	rm -f source.zip
	cd Irrlicht
	rm -r zlib jpeglib
	sed -i \
		-e 's:zlib/zlib\.h:zlib.h:' \
		CZipReader.cpp || die "zlib sed"
	sed -i \
		-e '/include/s:jpeglib/::' \
		CImageLoaderJPG.h || die "jpeg sed"
#	sed -i \
#		-e '1i#define GL_GLEXT_PROTOTYPES' \
#		-e '2i#include <GL/glxext.h>' \
#		CVideoOpenGL.cpp || die "opengl sed"
}

src_compile() {
	emake -C source/Irrlicht || die "emake failed"
}

src_install() {
	dolib.a lib/Linux/libIrrlicht.a || die "dolib.a failed"
	insinto /usr/include/${PN}
	doins include/* || die "doins failed"
	dodoc changes.txt readme.txt
	if use doc ; then
		cp -r examples media "${D}"/usr/share/doc/${PF}/ || die "cp failed"
	fi
}