games-util/gamemode-9999.ebuild

gamemode-9999.ebuild (text/plain), 2.35 KB, created by Kai Krakow on 2018-09-20 00:09:30 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

MULTILIB_COMPAT=( abi_x86_{32,64} )

inherit linux-info meson multilib-minimal ninja-utils user

DESCRIPTION="Optimise Linux system performance on demand"
HOMEPAGE="https://github.com/FeralInteractive/gamemode"

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="https://github.com/FeralInteractive/gamemode.git"
	inherit git-r3
else
	SRC_URI="https://github.com/FeralInteractive/gamemode/releases/download/${PV}/${P}.tar.xz"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="BSD"
SLOT="0"
IUSE=""

RDEPEND="
	>=sys-apps/systemd-236[${MULTILIB_USEDEP}]
"
DEPEND="${RDEPEND}"

# see "https://github.com/FeralInteractive/gamemode/blob/master/README.md"
CONFIG_CHECK="~SCHED_MUQSS ~SCHED_PDS"

ERROR_SCHED_MUQSS="CONFIG_SCHED_MUQSS: is optional unless you wish to use SCHED_ISO scheduling (sys-kernel/ck-sources)"
ERROR_SCHED_PDS="CONFIG_SCHED_PDS: is optional unless you wish to use SCHED_ISO scheduling (sys-kernel/pf-sources)"

multilib_src_configure() {
	local myconf=()
	if ! multilib_is_native_abi; then
		myconf+=(
			-Dwith-examples=false
			-Dwith-daemon=false
		)
	fi
	meson_src_configure "${myconf[@]}"
}

multilib_src_compile() {
	eninja
}

multilib_src_install() {
	DESTDIR="${D}" eninja install
	insinto /etc/security/limits.d
	newins - 45-gamemode.conf <<-EOF
		@gamemode - nice -10
	EOF
}

pkg_postinst() {
	elog
	elog "GameMode needs a kernel capable of SCHED_ISO to use its soft realtime feature."
	elog "Examples of kernels providing that are sys-kernel/ck-source and sys-kernel/pf-sources."
	elog

	enewgroup gamemode
	elog "GameMode can renice your games. You need to be in the gamemode group for this to work."
	elog "Run the following command as root to add your user:"
	elog "# groupmems -g gamemode -a USER      # with USER = your user name"

	elog
	elog "Run the following commands as your user (not as root) to enable gamemode:"
	elog "# systemctl --user daemon-reload     # Reload the unit files"
	elog "# systemctl --user enable gamemoded  # Enables the gamemoded daemon on future restarts"
	elog "# systemctl --user start gamemoded   # This starts the gamemoded daemon"
	elog
	elog "Add 'LD_PRELOAD=\$LD_PRELOAD:/usr/\$LIB/libgamemodeauto.so %command%'"
	elog "to the start options of any steam game to enable the performance"
	elog "governor as you start the game."
	elog
}