new ebuild (removed RESTRICT, src_compile and made for loop variable local)

qcachegrind-18.04.3.ebuild (text/plain), 1003 bytes, created by Markus Fischer on 2018-08-03 13:08:06 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit desktop gnome2-utils qmake-utils xdg-utils

# from kde5.eclass _calculate_src_uri
SRC_URI="mirror://kde/stable/applications/${PV}/src/kcachegrind-${PV}.tar.xz"

DESCRIPTION="Qt frontend for Cachegrind"
HOMEPAGE="https://kcachegrind.github.io/html/Home.html"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

# dbus might be optional
RDEPEND="dev-qt/qtcore:5
	dev-qt/qtdbus:5
	dev-qt/qtgui:5
	dev-qt/qtwidgets:5"

DEPEND="app-arch/xz-utils ${RDEPEND}"

S="${WORKDIR}/kcachegrind-${PV}"

src_configure() {
	eqmake5
}

src_install() {
	local size
	dobin qcachegrind/qcachegrind
	domenu qcachegrind/qcachegrind.desktop
	for size in 32 48 64 128; do
		newicon -s ${size} kcachegrind/${size}-apps-kcachegrind.png qcachegrind.png
	done
}

pkg_postinst() {
	xdg_desktop_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	xdg_desktop_database_update
	gnome2_icon_cache_update
}