New ebuild

gxine-0.4.2.ebuild (text/plain), 1.65 KB, created by Simon Holm Thøgersen on 2005-03-22 21:17:17 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils nsplugins fdo-mime

DESCRIPTION="GTK+ Front-End for libxine"
HOMEPAGE="http://xine.sourceforge.net/"
LICENSE="GPL-2"

# media-libs/libpng is not needed as dependency, gtk+-2 depends on it (though
# it didn't a long time ago).
# IUSE X haven't got any effect, so it has been removed. 
DEPEND="
	>=dev-lang/spidermonkey-1.5_rc6-r1
	>=media-libs/xine-lib-1_beta10
	>=x11-libs/gtk+-2.4
	>=dev-libs/glib-2.4
	lirc? ( app-misc/lirc )"

#gettext and lirc here?
RDEPEND="nls? ( sys-devel/gettext )"

IUSE="nls lirc mozilla"

SLOT="0"
KEYWORDS="~x86 ~ppc sparc ~amd64 ~ppc64"

SRC_URI="mirror://sourceforge/xine/${P}.tar.gz"

src_unpack() {
	unpack ${A}
	cd ${S}
	# gxine-0.4.2 isn't really supposed to be compiled against this version of
	# xine-lib, so we're doing some tricks with sed as suggested in bug #1164701
	# on the project page on sf.net. Fix planned for 0.4.3.
	sed -i -re 's%<xine/xmlparser.h>%"xmlparser.h"%' src/*.[ch]
	epatch ${FILESDIR}/${P}-menu-fix.patch
}

src_compile() {
	local myconf
	myconf="${myconf} $(use_enable nls) $(use_enable lirc)"
	econf ${myconf} || die
	emake || die
}

src_install() {
	make DESTDIR=${D} \
		docdir=/usr/share/doc/${PF} \
		docsdir=/usr/share/doc/${PF} \
		install || die

	dodoc AUTHORS COPYING ChangeLog INSTALL NEWS README

	insinto /usr/share/pixmaps
	doins pixmaps/gxine-logo.png

	#This is not right yet, getting complaints about link already existing.
	use mozilla && inst_plugin /usr/$(get_libdir)/gxine/gxineplugin.so
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}