sway-9999.ebuild

sway-9999.ebuild (text/plain), 1.33 KB, created by Alex Xu (Hello71) on 2018-07-23 00:03:54 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit git-r3 eutils meson

DESCRIPTION="i3-compatible Wayland window manager"
HOMEPAGE="http://swaywm.org/"
EGIT_REPO_URI="https://github.com/swaywm/sway.git"

LICENSE="MIT"
SLOT="0"
KEYWORDS=""
IUSE="elogind +gdk-pixbuf systemd +wallpapers zsh-completion"

RDEPEND="
	elogind? ( sys-auth/elogind )
	gdk-pixbuf? ( x11-libs/gdk-pixbuf )
	systemd? ( sys-apps/systemd )
	dev-libs/json-c:0=
	dev-libs/libinput
	dev-libs/libpcre
	dev-libs/wayland
	=dev-libs/wlroots-9999[elogind=,systemd=]
	sys-libs/libcap
	virtual/pam
	x11-libs/cairo
	x11-libs/libxcb
	x11-libs/libxkbcommon
	x11-libs/pango
	x11-libs/pixman
"

DEPEND="${RDEPEND}
	app-text/scdoc
	virtual/pkgconfig
"

meson_use_patch() {
	if use "$1"; then
		sed -i -e "/dependency(${2:-$1}/s/, *required: .*)/)/" meson.build || die
	else
		sed -i -e "/dependency(${2:-$1}/s/=.*/=disabler()/" meson.build || die
	fi
}

src_prepare() {
	default

	meson_use_patch elogind
	meson_use_patch systemd
	meson_use_patch gdk-pixbuf
}

src_configure() {
	local emesonargs=(
		$(meson_use wallpapers default_wallpaper)
		$(meson_use zsh-completion zsh_completions)
	)

	meson_src_configure
}

pkg_postinst() {
	optfeature "X11 applications support" dev-libs/wlroots[xwayland] x11-base/xorg-server[wayland]
}