newscache-1.2_rc6.ebuild

newscache-1.2_rc6.ebuild (text/plain), 1.49 KB, created by Tomislav Filipcic on 2005-03-17 19:05:30 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_P="NewsCache-1.2rc6"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="A free cache server for USENET News"
HOMEPAGE="http://www.linuxhacker.at/newscache/"
SRC_URI="http://www.linuxhacker.at/linux/downloads/src/${MY_P}.tar.gz
	http://www.linuxhacker.at/linux/downloads/src/${MY_P}-patch1.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc pam debug"

DEPEND="net-libs/socket++"

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch ${DISTDIR}/${MY_P}-patch1.gz || die "patch1 failed"
}

src_compile() {
	local myconf
	myconf="--sysconfdir=/etc/newscache"
	use pam && myconf="$myconf --with-pam"
	use debug && myconf="$myconf --enable-debug"

	einfo "Running autogen"
	WANT_AUTOMAKE=1.7 ./autogen || die "autogen failed"

	econf ${myconf} || die "econf failed"
	emake || die "emake failed"

	if use doc ; then
		cd ${S}/doc
		einfo "Building HTML documentation"
		makeinfo --html -I . -o html NewsCache.texinfo || die "makeinfo failed"
	fi
}

src_install() {
	make DESTDIR="${D}" install || die "install failed"
	exeinto /etc/init.d; newexe ${FILESDIR}/newscache-init newscache

	exeinto /etc/cron.daily; doexe ${FILESDIR}/newscache.cron	

	dodoc AUTHORS ChangeLog NEWS README* THANKS TODO || die "dodoc failed"

	if use doc ; then
		dohtml doc/html/* || die "dohtml failed"
		dodoc doc/*.txt
	fi
}

pkg_postinst() {
	mkdir -p ${ROOT}/var/cache/newscache/
	chown -R news:news ${ROOT}/var/cache/newscache
}