photoqt-1.7.1.ebuild

photoqt-1.7.1.ebuild (text/plain), 1.34 KB, created by Frank Krömmelbein on 2018-06-11 07:32:04 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit cmake-utils gnome2-utils xdg-utils

DESCRIPTION="Simple but powerful Qt-based image viewer"
HOMEPAGE="https://photoqt.org/"
SRC_URI="https://photoqt.org/pkgs/${P}.tar.gz"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="devil exiv2 freeimage graphicsmagick pdf raw"

RDEPEND="
	dev-qt/qtcore:5
	dev-qt/qtdeclarative:5
	dev-qt/qtgraphicaleffects:5
	dev-qt/qtgui:5
	dev-qt/qtimageformats:5
	dev-qt/qtmultimedia:5[qml]
	dev-qt/qtnetwork:5
	dev-qt/qtquickcontrols:5
	dev-qt/qtsql:5
	dev-qt/qtsvg:5
	dev-qt/qtwidgets:5
	dev-qt/qtxml:5
	app-arch/libarchive
	app-arch/unrar
	exiv2? ( media-gfx/exiv2:= )
	graphicsmagick? ( >=media-gfx/graphicsmagick-1.3.20:= )
	devil? ( media-libs/devil )
	freeimage? ( media-libs/freeimage )
	pdf? ( app-text/poppler[qt5] )
	raw? ( media-libs/libraw:= )
"
DEPEND="${RDEPEND}
	dev-qt/linguist-tools:5
"

src_configure() {
	local mycmakeargs=(
		-DEXIV2=$(usex exiv2)
		-DGM=$(usex graphicsmagick)
		-DDEVIL=$(usex devil)
		-DFREEIMAGE=$(usex freeimage)
		-DPOPPLER=$(usex pdf)
		-DRAW=$(usex raw)
	)
	cmake-utils_src_configure
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
	xdg_desktop_database_update
}

pkg_postrm() {
	gnome2_icon_cache_update
	xdg_desktop_database_update
}