version 1.2.3, slot 1.2 (zero-latency edition)

ir_lv2-1.2.3.ebuild (text/plain), 1.39 KB, created by Nikita Zlobin on 2018-05-17 16:26:32 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit toolchain-funcs flag-o-matic multilib

MY_P="${P/_/.}"
DESCRIPTION="LV2 convolver plugin especially for creating reverb effects"
HOMEPAGE="https://tomszilagyi.github.io/plugins/ir.lv2/"
SRC_URI="https://github.com/tomszilagyi/ir.lv2/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="1.2"
KEYWORDS="~amd64 ~x86"
IUSE="tools"

RDEPEND=">=media-libs/zita-convolver-3
	>=x11-libs/gtk+-2.16:2
	media-libs/lv2
	media-libs/libsndfile
	media-libs/libsamplerate
	!media-plugins/ir_lv2:1.3"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

S=${WORKDIR}/${PN/_/.}-${PV}
DOCS=( README.md sshot.png ChangeLog )

src_prepare() {
	default
	sed -i -e 's/g++/$(CXX)/' -e 's/gcc/$(CC)/' Makefile || die #respect CC/CXX
	sed -i -e 's/\(^C4CFLAGS =.*\) -O2.*/\1 $(CFLAGS)/' Makefile || die #respect CFLAGS
	sed -i -e 's/\(^CPPFLAGS +=.*\) -O2.*/\1 $(CXXFLAGS)/' Makefile || die #respect CXXFLAGS
}

src_compile() {
	tc-export CC CXX
	emake || die
	use tools && emake convert4chan
}

src_install() {
	emake INSTDIR="${D}/usr/$(get_libdir)/lv2/ir.lv2" install || die
	use tools && newbin convert4chan ir_convert4chan
}

pkg_postinst() {
	if ! has_version "media-plugins/ir_lv2:1.3" ; then
		einfo "ir.lv2 1.2 provides zero latency by cost of automation."
		einfo "If you need automation, use version 1.3 instead."
	fi
}