raine-0.64.15.ebuild

raine-0.64.15.ebuild (text/plain), 1.30 KB, created by Pacho Ramos on 2018-04-29 16:04:24 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit flag-o-matic

DESCRIPTION="R A I N E  M680x0 Arcade Emulation"
HOMEPAGE="http://raine.1emulation.com/ https://github.com/zelurker/raine"
SRC_URI="https://github.com/zelurker/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="Artistic"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="
	dev-cpp/muParser
	media-libs/libsdl[sound,joystick,video]
	>=sys-libs/zlib-1.2.5.1-r1
	media-libs/sdl-image[png]
	media-libs/sdl-ttf
"
DEPEND="${RDEPEND}
	dev-lang/nasm
	app-arch/unzip
"

src_prepare() {
	default
	echo > detect-cpu
	echo > cpuinfo
	sed -i \
		-e "/^NEO/s:^:#:" \
		-e "s:nasmw:nasm:" \
		-e "/bindir/s:=.*:=\$(DESTDIR)/usr/bin:" \
		-e "/sharedir =/s:=.*:=\$(DESTDIR)/usr/share:" \
		-e "/mandir/s:=.*:=\$(DESTDIR)/usr/share/man/man6:" \
		makefile || die

	# Respect LDFLAGS
	sed -i -e 's/$(LDV) $(LFLAGS)/$(LDV) $(LDFLAGS) $(LFLAGS)/' makefile || die

	# https://github.com/zelurker/raine/issues/21
	eapply "${FILESDIR}"/${PN}-0.64.15-gentoo-detection.patch

	append-ldflags -Wl,-z,noexecstack
}

src_compile() {
	local myopts

	emake \
		_MARCH="${CFLAGS}" \
		VERBOSE=1 \
		${myopts}
}

src_install() {
	default
	keepdir /usr/share/${PN}/{roms,artwork,emudx,scripts/raine}
	dodoc docs/readme.txt
}