rt2400-1.2.2_beta2.ebuild

rt2400-1.2.2_beta2.ebuild (text/plain), 1.11 KB, created by Stefan Schweizer (RETIRED) on 2005-03-04 05:49:01 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/rt2400/rt2400-1.1.0_beta2.ebuild,v 1.1 2005/02/21 21:15:28 genstef Exp $

inherit eutils linux-mod kde-functions
set-qtdir 3

MY_P="${P/_beta/-b}"
DESCRIPTION="Driver for the RaLink RT2400 wireless chipset"
HOMEPAGE="http://rt2x00.serialmonkey.com"
SRC_URI="http://rt2x00.serialmonkey.com/${MY_P}.tar.gz"
LICENSE="GPL-2"

KEYWORDS="~x86"
IUSE="qt"
DEPEND="net-wireless/wireless-tools
	qt? ( >=x11-libs/qt-3 )"

S=${WORKDIR}/${MY_P/-b*}
MODULE_NAMES="rt2400(net:${S}/Module)"
CONFIG_CHECK="NET_RADIO"
MODULESD_RT2400_ALIASES=('ra? rt2400')


pkg_setup() {
	linux-mod_pkg_setup
	if use_m
	then BUILD_PARAMS="-C ${KV_DIR} M=${S}/Module"
		 BUILD_TARGETS="modules"
	else die "please use a kernel >=2.6.6"
	fi
}

src_compile() {
	if useq qt; then
		cd ${S}/Utility
		qmake -o Makefile raconfig2400.pro
		emake || die "make Utilities failed"
	fi

	linux-mod_src_compile
}

src_install() {
	linux-mod_src_install

	useq qt && dobin ${S}/Utility/RaConfig2400

	dodoc CHANGELOG FAQ THANKS
}