qt5ct-0.35-r1.ebuild adds appropriate QT_LOGGING_RULES to /etc/env.d/98qt5ct

qt5ct-0.35-r1.ebuild (text/plain), 1.14 KB, created by Dmitriy Dyomin on 2018-03-27 10:02:21 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit qmake-utils

DESCRIPTION="Qt5 configuration tool, similar to qtconfig for Qt4"
HOMEPAGE="https://sourceforge.net/projects/qt5ct/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+dbus"

RDEPEND="
	dev-qt/qtcore:5
	dev-qt/qtgui:5=
	dev-qt/qtwidgets:5
	dbus? (
		dev-qt/qtdbus:5
		dev-qt/qtgui:5[dbus]
	)
"
DEPEND="${RDEPEND}
	dev-qt/linguist-tools:5
"

PATCHES=( "${FILESDIR}/${P}-fix-qtdbus-automagic.patch" )

src_configure() {
	eqmake5 DISABLE_DBUS=$(usex !dbus 1 0)
}

src_install() {
	emake INSTALL_ROOT="${D}" install
	einstalldocs

	echo 'QT_QPA_PLATFORMTHEME=qt5ct' > "${T}"/98${PN} || die
	echo 'QT_LOGGING_RULES="qt5ct.debug=false"' >> "${T}"/98${PN} || die 
	doenvd "${T}"/98${PN}
}

pkg_postinst() {
	if [[ -z ${REPLACING_VERSIONS} ]]; then
		ewarn "qt5ct configuration won't be applied to the currently running sessions."
		ewarn "Please relogin."
	fi
	if ! has_version 'dev-qt/qtsvg:5'; then
		elog
		elog "For SVG icon themes, please install 'dev-qt/qtsvg:5'."
		elog
	fi
}