coin-9999.ebuild

coin-9999.ebuild (text/plain), 1.73 KB, created by Fabio Rossi on 2018-02-02 17:12:37 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

EHG_REPO_URI="https://bitbucket.org/Coin3D/coin"
EHG_REVISION="CMake"
EHG_CONFIG="subpaths.\.\./(.*)=https://bitbucket.org/Coin3D/\1"
inherit mercurial cmake-utils

MY_P=${P/c/C}

DESCRIPTION="A high-level 3D graphics toolkit, fully compatible with SGI Open Inventor 2.1"
HOMEPAGE="https://bitbucket.org/Coin3D/coin/wiki/Home"

LICENSE="|| ( GPL-2 PEL )"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ppc ~ppc64 x86 ~amd64-linux ~x86-linux"
SLOT="0"
IUSE="debug doc javascript openal simage static-libs threads"

RDEPEND="
	app-arch/bzip2
	dev-libs/expat
	media-libs/fontconfig
	media-libs/freetype:2
	virtual/opengl
	virtual/glu
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/libX11
	x11-libs/libXext
	sys-libs/zlib
	javascript? ( dev-lang/spidermonkey:0 )
	openal? ( media-libs/openal )
	simage? ( media-libs/simage )
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	x11-proto/xextproto
	doc? ( app-doc/doxygen )
"
S="${WORKDIR}/${MY_P}"

PATCHES=(
	"${FILESDIR}"/${PN}-3.1.3-gcc-4.7.patch
	"${FILESDIR}"/${PN}-3.1.3-freetype251.patch
)

DOCS=(
	AUTHORS FAQ FAQ.legal NEWS README RELNOTES THANKS
	docs/{HACKING,oiki-launch.txt}
)

src_configure() {
	local mycmakeargs=(
		-DHAVE_MAN=NO
		-DHAVE_VRML97=YES
		-DHAVE_NODEKITS=YES
		-DHAVE_DRAGGERS=YES
		-DHAVE_MANIPULATORS=YES
		-DHAVE_3DS_IMPORT_CAPABILITIES=YES
		-DCOIN_BUILD_DOCUMENTATION=$(usex doc)
		-DCOIN_HAVE_JAVASCRIPT=$(usex javascript)
		-DSIMAGE_RUNTIME_LINKING=$(usex simage)
		-DCOIN_BUILD_SHARED_LIBS=$(usex static-libs no yes)
		-DHAVE_SOUND=$(usex openal)
		-DCOIN_THREADSAFE=$(usex threads)
		-DCMAKE_INSTALL_INCLUDEDIR=include/coin
		-DCMAKE_INSTALL_DOCDIR=share/doc/${P}
		)
	cmake-utils_src_configure
}