Updated ebuild.

mandoc-1.14.3-r1.ebuild (text/plain), 1.24 KB, created by Wolfgang Müller on 2018-01-08 01:51:48 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

DESCRIPTION="A suite of tools compiling mdoc from the OpenBSD project"
HOMEPAGE="http://mdocml.bsd.lv/"
SRC_URI="http://mdocml.bsd.lv/snapshots/${P}.tar.gz"
PATCHES=( "${FILESDIR}/${P}-bzip.patch" )

LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RESTRICT="mirror"

IUSE="+cron static"

RDEPEND="static? ( sys-libs/zlib[static-libs(+)] app-arch/bzip2[static-libs(+)] )
		 !sys-apps/man-db !sys-apps/man !sys-apps/groff"

DEPEND="static? ( sys-libs/zlib )"

src_configure() {
	cp "${FILESDIR}/configure.local" . || die

	# Add Gentoo CFLAGS
	echo 'CFLAGS="$CFLAGS' ${CFLAGS}\" >> configure.local

	if use static; then
		echo 'LDFLAGS="$LDFLAGS -static"' >> configure.local
	fi

	default
}

src_install() {
	default

	if use cron; then
		exeinto /etc/cron.daily
		newexe "${FILESDIR}"/mandoc.cron mandoc
	fi
}

pkg_postinst() {
	elog "In order to enable mandoc's apropos and man -k functionality,"
	elog "the appropriate mandoc.db files need to be created. This can be"
	elog "achieved by running makewhatis as root (sudo will not work)."
	elog
	elog "If the cron use-flag is enabled, a cron.daily entry that calls"
	elog "makewhatis will be installed."
}